Created
August 11, 2020 08:35
-
-
Save rahuldamodar94/1ebef5fc1c1b75bee2fda4633f1be981 to your computer and use it in GitHub Desktop.
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
// File: @openzeppelin/contracts/utils/Address.sol | |
// SPDX-License-Identifier: MIT | |
pragma solidity ^0.6.2; | |
/** | |
* @dev Collection of functions related to the address type | |
*/ | |
library Address { | |
/** | |
* @dev Returns true if `account` is a contract. | |
* | |
* [IMPORTANT] | |
* ==== | |
* It is unsafe to assume that an address for which this function returns | |
* false is an externally-owned account (EOA) and not a contract. | |
* | |
* Among others, `isContract` will return false for the following | |
* types of addresses: | |
* | |
* - an externally-owned account | |
* - a contract in construction | |
* - an address where a contract will be created | |
* - an address where a contract lived, but was destroyed | |
* ==== | |
*/ | |
function isContract(address account) internal view returns (bool) { | |
// According to EIP-1052, 0x0 is the value returned for not-yet created accounts | |
// and 0xc5d2460186f7233c927e7db2dcc703c0e500b653ca82273b7bfad8045d85a470 is returned | |
// for accounts without code, i.e. `keccak256('')` | |
bytes32 codehash; | |
bytes32 accountHash = 0xc5d2460186f7233c927e7db2dcc703c0e500b653ca82273b7bfad8045d85a470; | |
// solhint-disable-next-line no-inline-assembly | |
assembly { codehash := extcodehash(account) } | |
return (codehash != accountHash && codehash != 0x0); | |
} | |
/** | |
* @dev Replacement for Solidity's `transfer`: sends `amount` wei to | |
* `recipient`, forwarding all available gas and reverting on errors. | |
* | |
* https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost | |
* of certain opcodes, possibly making contracts go over the 2300 gas limit | |
* imposed by `transfer`, making them unable to receive funds via | |
* `transfer`. {sendValue} removes this limitation. | |
* | |
* https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more]. | |
* | |
* IMPORTANT: because control is transferred to `recipient`, care must be | |
* taken to not create reentrancy vulnerabilities. Consider using | |
* {ReentrancyGuard} or the | |
* https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern]. | |
*/ | |
function sendValue(address payable recipient, uint256 amount) internal { | |
require(address(this).balance >= amount, "Address: insufficient balance"); | |
// solhint-disable-next-line avoid-low-level-calls, avoid-call-value | |
(bool success, ) = recipient.call{ value: amount }(""); | |
require(success, "Address: unable to send value, recipient may have reverted"); | |
} | |
/** | |
* @dev Performs a Solidity function call using a low level `call`. A | |
* plain`call` is an unsafe replacement for a function call: use this | |
* function instead. | |
* | |
* If `target` reverts with a revert reason, it is bubbled up by this | |
* function (like regular Solidity function calls). | |
* | |
* Returns the raw returned data. To convert to the expected return value, | |
* use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`]. | |
* | |
* Requirements: | |
* | |
* - `target` must be a contract. | |
* - calling `target` with `data` must not revert. | |
* | |
* _Available since v3.1._ | |
*/ | |
function functionCall(address target, bytes memory data) internal returns (bytes memory) { | |
return functionCall(target, data, "Address: low-level call failed"); | |
} | |
/** | |
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with | |
* `errorMessage` as a fallback revert reason when `target` reverts. | |
* | |
* _Available since v3.1._ | |
*/ | |
function functionCall(address target, bytes memory data, string memory errorMessage) internal returns (bytes memory) { | |
return _functionCallWithValue(target, data, 0, errorMessage); | |
} | |
/** | |
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], | |
* but also transferring `value` wei to `target`. | |
* | |
* Requirements: | |
* | |
* - the calling contract must have an ETH balance of at least `value`. | |
* - the called Solidity function must be `payable`. | |
* | |
* _Available since v3.1._ | |
*/ | |
function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) { | |
return functionCallWithValue(target, data, value, "Address: low-level call with value failed"); | |
} | |
/** | |
* @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but | |
* with `errorMessage` as a fallback revert reason when `target` reverts. | |
* | |
* _Available since v3.1._ | |
*/ | |
function functionCallWithValue(address target, bytes memory data, uint256 value, string memory errorMessage) internal returns (bytes memory) { | |
require(address(this).balance >= value, "Address: insufficient balance for call"); | |
return _functionCallWithValue(target, data, value, errorMessage); | |
} | |
function _functionCallWithValue(address target, bytes memory data, uint256 weiValue, string memory errorMessage) private returns (bytes memory) { | |
require(isContract(target), "Address: call to non-contract"); | |
// solhint-disable-next-line avoid-low-level-calls | |
(bool success, bytes memory returndata) = target.call{ value: weiValue }(data); | |
if (success) { | |
return returndata; | |
} else { | |
// Look for revert reason and bubble it up if present | |
if (returndata.length > 0) { | |
// The easiest way to bubble the revert reason is using memory via assembly | |
// solhint-disable-next-line no-inline-assembly | |
assembly { | |
let returndata_size := mload(returndata) | |
revert(add(32, returndata), returndata_size) | |
} | |
} else { | |
revert(errorMessage); | |
} | |
} | |
} | |
} | |
/** | |
* @dev Library for managing | |
* https://en.wikipedia.org/wiki/Set_(abstract_data_type)[sets] of primitive | |
* types. | |
* | |
* Sets have the following properties: | |
* | |
* - Elements are added, removed, and checked for existence in constant time | |
* (O(1)). | |
* - Elements are enumerated in O(n). No guarantees are made on the ordering. | |
* | |
* ``` | |
* contract Example { | |
* // Add the library methods | |
* using EnumerableSet for EnumerableSet.AddressSet; | |
* | |
* // Declare a set state variable | |
* EnumerableSet.AddressSet private mySet; | |
* } | |
* ``` | |
* | |
* As of v3.0.0, only sets of type `address` (`AddressSet`) and `uint256` | |
* (`UintSet`) are supported. | |
*/ | |
library EnumerableSet { | |
// To implement this library for multiple types with as little code | |
// repetition as possible, we write it in terms of a generic Set type with | |
// bytes32 values. | |
// The Set implementation uses private functions, and user-facing | |
// implementations (such as AddressSet) are just wrappers around the | |
// underlying Set. | |
// This means that we can only create new EnumerableSets for types that fit | |
// in bytes32. | |
struct Set { | |
// Storage of set values | |
bytes32[] _values; | |
// Position of the value in the `values` array, plus 1 because index 0 | |
// means a value is not in the set. | |
mapping (bytes32 => uint256) _indexes; | |
} | |
/** | |
* @dev Add a value to a set. O(1). | |
* | |
* Returns true if the value was added to the set, that is if it was not | |
* already present. | |
*/ | |
function _add(Set storage set, bytes32 value) private returns (bool) { | |
if (!_contains(set, value)) { | |
set._values.push(value); | |
// The value is stored at length-1, but we add 1 to all indexes | |
// and use 0 as a sentinel value | |
set._indexes[value] = set._values.length; | |
return true; | |
} else { | |
return false; | |
} | |
} | |
/** | |
* @dev Removes a value from a set. O(1). | |
* | |
* Returns true if the value was removed from the set, that is if it was | |
* present. | |
*/ | |
function _remove(Set storage set, bytes32 value) private returns (bool) { | |
// We read and store the value's index to prevent multiple reads from the same storage slot | |
uint256 valueIndex = set._indexes[value]; | |
if (valueIndex != 0) { // Equivalent to contains(set, value) | |
// To delete an element from the _values array in O(1), we swap the element to delete with the last one in | |
// the array, and then remove the last element (sometimes called as 'swap and pop'). | |
// This modifies the order of the array, as noted in {at}. | |
uint256 toDeleteIndex = valueIndex - 1; | |
uint256 lastIndex = set._values.length - 1; | |
// When the value to delete is the last one, the swap operation is unnecessary. However, since this occurs | |
// so rarely, we still do the swap anyway to avoid the gas cost of adding an 'if' statement. | |
bytes32 lastvalue = set._values[lastIndex]; | |
// Move the last value to the index where the value to delete is | |
set._values[toDeleteIndex] = lastvalue; | |
// Update the index for the moved value | |
set._indexes[lastvalue] = toDeleteIndex + 1; // All indexes are 1-based | |
// Delete the slot where the moved value was stored | |
set._values.pop(); | |
// Delete the index for the deleted slot | |
delete set._indexes[value]; | |
return true; | |
} else { | |
return false; | |
} | |
} | |
/** | |
* @dev Returns true if the value is in the set. O(1). | |
*/ | |
function _contains(Set storage set, bytes32 value) private view returns (bool) { | |
return set._indexes[value] != 0; | |
} | |
/** | |
* @dev Returns the number of values on the set. O(1). | |
*/ | |
function _length(Set storage set) private view returns (uint256) { | |
return set._values.length; | |
} | |
/** | |
* @dev Returns the value stored at position `index` in the set. O(1). | |
* | |
* Note that there are no guarantees on the ordering of values inside the | |
* array, and it may change when more values are added or removed. | |
* | |
* Requirements: | |
* | |
* - `index` must be strictly less than {length}. | |
*/ | |
function _at(Set storage set, uint256 index) private view returns (bytes32) { | |
require(set._values.length > index, "EnumerableSet: index out of bounds"); | |
return set._values[index]; | |
} | |
// AddressSet | |
struct AddressSet { | |
Set _inner; | |
} | |
/** | |
* @dev Add a value to a set. O(1). | |
* | |
* Returns true if the value was added to the set, that is if it was not | |
* already present. | |
*/ | |
function add(AddressSet storage set, address value) internal returns (bool) { | |
return _add(set._inner, bytes32(uint256(value))); | |
} | |
/** | |
* @dev Removes a value from a set. O(1). | |
* | |
* Returns true if the value was removed from the set, that is if it was | |
* present. | |
*/ | |
function remove(AddressSet storage set, address value) internal returns (bool) { | |
return _remove(set._inner, bytes32(uint256(value))); | |
} | |
/** | |
* @dev Returns true if the value is in the set. O(1). | |
*/ | |
function contains(AddressSet storage set, address value) internal view returns (bool) { | |
return _contains(set._inner, bytes32(uint256(value))); | |
} | |
/** | |
* @dev Returns the number of values in the set. O(1). | |
*/ | |
function length(AddressSet storage set) internal view returns (uint256) { | |
return _length(set._inner); | |
} | |
/** | |
* @dev Returns the value stored at position `index` in the set. O(1). | |
* | |
* Note that there are no guarantees on the ordering of values inside the | |
* array, and it may change when more values are added or removed. | |
* | |
* Requirements: | |
* | |
* - `index` must be strictly less than {length}. | |
*/ | |
function at(AddressSet storage set, uint256 index) internal view returns (address) { | |
return address(uint256(_at(set._inner, index))); | |
} | |
// UintSet | |
struct UintSet { | |
Set _inner; | |
} | |
/** | |
* @dev Add a value to a set. O(1). | |
* | |
* Returns true if the value was added to the set, that is if it was not | |
* already present. | |
*/ | |
function add(UintSet storage set, uint256 value) internal returns (bool) { | |
return _add(set._inner, bytes32(value)); | |
} | |
/** | |
* @dev Removes a value from a set. O(1). | |
* | |
* Returns true if the value was removed from the set, that is if it was | |
* present. | |
*/ | |
function remove(UintSet storage set, uint256 value) internal returns (bool) { | |
return _remove(set._inner, bytes32(value)); | |
} | |
/** | |
* @dev Returns true if the value is in the set. O(1). | |
*/ | |
function contains(UintSet storage set, uint256 value) internal view returns (bool) { | |
return _contains(set._inner, bytes32(value)); | |
} | |
/** | |
* @dev Returns the number of values on the set. O(1). | |
*/ | |
function length(UintSet storage set) internal view returns (uint256) { | |
return _length(set._inner); | |
} | |
/** | |
* @dev Returns the value stored at position `index` in the set. O(1). | |
* | |
* Note that there are no guarantees on the ordering of values inside the | |
* array, and it may change when more values are added or removed. | |
* | |
* Requirements: | |
* | |
* - `index` must be strictly less than {length}. | |
*/ | |
function at(UintSet storage set, uint256 index) internal view returns (uint256) { | |
return uint256(_at(set._inner, index)); | |
} | |
} | |
/* | |
* @dev Provides information about the current execution context, including the | |
* sender of the transaction and its data. While these are generally available | |
* via msg.sender and msg.data, they should not be accessed in such a direct | |
* manner, since when dealing with GSN meta-transactions the account sending and | |
* paying for execution may not be the actual sender (as far as an application | |
* is concerned). | |
* | |
* This contract is only required for intermediate, library-like contracts. | |
*/ | |
abstract contract Context { | |
function _msgSender() internal view virtual returns (address payable) { | |
return msg.sender; | |
} | |
function _msgData() internal view virtual returns (bytes memory) { | |
this; // silence state mutability warning without generating bytecode - see https://github.com/ethereum/solidity/issues/2691 | |
return msg.data; | |
} | |
} | |
/** | |
* @dev Contract module that allows children to implement role-based access | |
* control mechanisms. | |
* | |
* Roles are referred to by their `bytes32` identifier. These should be exposed | |
* in the external API and be unique. The best way to achieve this is by | |
* using `public constant` hash digests: | |
* | |
* ``` | |
* bytes32 public constant MY_ROLE = keccak256("MY_ROLE"); | |
* ``` | |
* | |
* Roles can be used to represent a set of permissions. To restrict access to a | |
* function call, use {hasRole}: | |
* | |
* ``` | |
* function foo() public { | |
* require(hasRole(MY_ROLE, msg.sender)); | |
* ... | |
* } | |
* ``` | |
* | |
* Roles can be granted and revoked dynamically via the {grantRole} and | |
* {revokeRole} functions. Each role has an associated admin role, and only | |
* accounts that have a role's admin role can call {grantRole} and {revokeRole}. | |
* | |
* By default, the admin role for all roles is `DEFAULT_ADMIN_ROLE`, which means | |
* that only accounts with this role will be able to grant or revoke other | |
* roles. More complex role relationships can be created by using | |
* {_setRoleAdmin}. | |
* | |
* WARNING: The `DEFAULT_ADMIN_ROLE` is also its own admin: it has permission to | |
* grant and revoke this role. Extra precautions should be taken to secure | |
* accounts that have been granted it. | |
*/ | |
abstract contract AccessControl is Context { | |
using EnumerableSet for EnumerableSet.AddressSet; | |
using Address for address; | |
struct RoleData { | |
EnumerableSet.AddressSet members; | |
bytes32 adminRole; | |
} | |
mapping (bytes32 => RoleData) private _roles; | |
bytes32 public constant DEFAULT_ADMIN_ROLE = 0x00; | |
/** | |
* @dev Emitted when `newAdminRole` is set as ``role``'s admin role, replacing `previousAdminRole` | |
* | |
* `DEFAULT_ADMIN_ROLE` is the starting admin for all roles, despite | |
* {RoleAdminChanged} not being emitted signaling this. | |
* | |
* _Available since v3.1._ | |
*/ | |
event RoleAdminChanged(bytes32 indexed role, bytes32 indexed previousAdminRole, bytes32 indexed newAdminRole); | |
/** | |
* @dev Emitted when `account` is granted `role`. | |
* | |
* `sender` is the account that originated the contract call, an admin role | |
* bearer except when using {_setupRole}. | |
*/ | |
event RoleGranted(bytes32 indexed role, address indexed account, address indexed sender); | |
/** | |
* @dev Emitted when `account` is revoked `role`. | |
* | |
* `sender` is the account that originated the contract call: | |
* - if using `revokeRole`, it is the admin role bearer | |
* - if using `renounceRole`, it is the role bearer (i.e. `account`) | |
*/ | |
event RoleRevoked(bytes32 indexed role, address indexed account, address indexed sender); | |
/** | |
* @dev Returns `true` if `account` has been granted `role`. | |
*/ | |
function hasRole(bytes32 role, address account) public view returns (bool) { | |
return _roles[role].members.contains(account); | |
} | |
/** | |
* @dev Returns the number of accounts that have `role`. Can be used | |
* together with {getRoleMember} to enumerate all bearers of a role. | |
*/ | |
function getRoleMemberCount(bytes32 role) public view returns (uint256) { | |
return _roles[role].members.length(); | |
} | |
/** | |
* @dev Returns one of the accounts that have `role`. `index` must be a | |
* value between 0 and {getRoleMemberCount}, non-inclusive. | |
* | |
* Role bearers are not sorted in any particular way, and their ordering may | |
* change at any point. | |
* | |
* WARNING: When using {getRoleMember} and {getRoleMemberCount}, make sure | |
* you perform all queries on the same block. See the following | |
* https://forum.openzeppelin.com/t/iterating-over-elements-on-enumerableset-in-openzeppelin-contracts/2296[forum post] | |
* for more information. | |
*/ | |
function getRoleMember(bytes32 role, uint256 index) public view returns (address) { | |
return _roles[role].members.at(index); | |
} | |
/** | |
* @dev Returns the admin role that controls `role`. See {grantRole} and | |
* {revokeRole}. | |
* | |
* To change a role's admin, use {_setRoleAdmin}. | |
*/ | |
function getRoleAdmin(bytes32 role) public view returns (bytes32) { | |
return _roles[role].adminRole; | |
} | |
/** | |
* @dev Grants `role` to `account`. | |
* | |
* If `account` had not been already granted `role`, emits a {RoleGranted} | |
* event. | |
* | |
* Requirements: | |
* | |
* - the caller must have ``role``'s admin role. | |
*/ | |
function grantRole(bytes32 role, address account) public virtual { | |
require(hasRole(_roles[role].adminRole, _msgSender()), "AccessControl: sender must be an admin to grant"); | |
_grantRole(role, account); | |
} | |
/** | |
* @dev Revokes `role` from `account`. | |
* | |
* If `account` had been granted `role`, emits a {RoleRevoked} event. | |
* | |
* Requirements: | |
* | |
* - the caller must have ``role``'s admin role. | |
*/ | |
function revokeRole(bytes32 role, address account) public virtual { | |
require(hasRole(_roles[role].adminRole, _msgSender()), "AccessControl: sender must be an admin to revoke"); | |
_revokeRole(role, account); | |
} | |
/** | |
* @dev Revokes `role` from the calling account. | |
* | |
* Roles are often managed via {grantRole} and {revokeRole}: this function's | |
* purpose is to provide a mechanism for accounts to lose their privileges | |
* if they are compromised (such as when a trusted device is misplaced). | |
* | |
* If the calling account had been granted `role`, emits a {RoleRevoked} | |
* event. | |
* | |
* Requirements: | |
* | |
* - the caller must be `account`. | |
*/ | |
function renounceRole(bytes32 role, address account) public virtual { | |
require(account == _msgSender(), "AccessControl: can only renounce roles for self"); | |
_revokeRole(role, account); | |
} | |
/** | |
* @dev Grants `role` to `account`. | |
* | |
* If `account` had not been already granted `role`, emits a {RoleGranted} | |
* event. Note that unlike {grantRole}, this function doesn't perform any | |
* checks on the calling account. | |
* | |
* [WARNING] | |
* ==== | |
* This function should only be called from the constructor when setting | |
* up the initial roles for the system. | |
* | |
* Using this function in any other way is effectively circumventing the admin | |
* system imposed by {AccessControl}. | |
* ==== | |
*/ | |
function _setupRole(bytes32 role, address account) internal virtual { | |
_grantRole(role, account); | |
} | |
/** | |
* @dev Sets `adminRole` as ``role``'s admin role. | |
* | |
* Emits a {RoleAdminChanged} event. | |
*/ | |
function _setRoleAdmin(bytes32 role, bytes32 adminRole) internal virtual { | |
emit RoleAdminChanged(role, _roles[role].adminRole, adminRole); | |
_roles[role].adminRole = adminRole; | |
} | |
function _grantRole(bytes32 role, address account) private { | |
if (_roles[role].members.add(account)) { | |
emit RoleGranted(role, account, _msgSender()); | |
} | |
} | |
function _revokeRole(bytes32 role, address account) private { | |
if (_roles[role].members.remove(account)) { | |
emit RoleRevoked(role, account, _msgSender()); | |
} | |
} | |
} | |
contract AccessControlMixin is AccessControl { | |
string private _revertMsg; | |
function _setupContractId(string memory contractId) internal { | |
_revertMsg = string(abi.encodePacked(contractId, ": INSUFFICIENT_PERMISSIONS")); | |
} | |
modifier only(bytes32 role) { | |
require( | |
hasRole(role, _msgSender()), | |
_revertMsg | |
); | |
_; | |
} | |
} | |
/* | |
* @author Hamdi Allam hamdi.allam97@gmail.com | |
* Please reach out with any questions or concerns | |
* https://github.com/hamdiallam/Solidity-RLP/blob/e681e25a376dbd5426b509380bc03446f05d0f97/contracts/RLPReader.sol | |
*/ | |
library RLPReader { | |
uint8 constant STRING_SHORT_START = 0x80; | |
uint8 constant STRING_LONG_START = 0xb8; | |
uint8 constant LIST_SHORT_START = 0xc0; | |
uint8 constant LIST_LONG_START = 0xf8; | |
uint8 constant WORD_SIZE = 32; | |
struct RLPItem { | |
uint256 len; | |
uint256 memPtr; | |
} | |
struct Iterator { | |
RLPItem item; // Item that's being iterated over. | |
uint256 nextPtr; // Position of the next item in the list. | |
} | |
/* | |
* @dev Returns the next element in the iteration. Reverts if it has not next element. | |
* @param self The iterator. | |
* @return The next element in the iteration. | |
*/ | |
function next(Iterator memory self) internal pure returns (RLPItem memory) { | |
require(hasNext(self)); | |
uint256 ptr = self.nextPtr; | |
uint256 itemLength = _itemLength(ptr); | |
self.nextPtr = ptr + itemLength; | |
return RLPItem(itemLength, ptr); | |
} | |
/* | |
* @dev Returns true if the iteration has more elements. | |
* @param self The iterator. | |
* @return true if the iteration has more elements. | |
*/ | |
function hasNext(Iterator memory self) internal pure returns (bool) { | |
RLPItem memory item = self.item; | |
return self.nextPtr < item.memPtr + item.len; | |
} | |
/* | |
* @param item RLP encoded bytes | |
*/ | |
function toRlpItem(bytes memory item) | |
internal | |
pure | |
returns (RLPItem memory) | |
{ | |
uint256 memPtr; | |
assembly { | |
memPtr := add(item, 0x20) | |
} | |
return RLPItem(item.length, memPtr); | |
} | |
/* | |
* @dev Create an iterator. Reverts if item is not a list. | |
* @param self The RLP item. | |
* @return An 'Iterator' over the item. | |
*/ | |
function iterator(RLPItem memory self) | |
internal | |
pure | |
returns (Iterator memory) | |
{ | |
require(isList(self)); | |
uint256 ptr = self.memPtr + _payloadOffset(self.memPtr); | |
return Iterator(self, ptr); | |
} | |
/* | |
* @param item RLP encoded bytes | |
*/ | |
function rlpLen(RLPItem memory item) internal pure returns (uint256) { | |
return item.len; | |
} | |
/* | |
* @param item RLP encoded bytes | |
*/ | |
function payloadLen(RLPItem memory item) internal pure returns (uint256) { | |
return item.len - _payloadOffset(item.memPtr); | |
} | |
/* | |
* @param item RLP encoded list in bytes | |
*/ | |
function toList(RLPItem memory item) | |
internal | |
pure | |
returns (RLPItem[] memory) | |
{ | |
require(isList(item)); | |
uint256 items = numItems(item); | |
RLPItem[] memory result = new RLPItem[](items); | |
uint256 memPtr = item.memPtr + _payloadOffset(item.memPtr); | |
uint256 dataLen; | |
for (uint256 i = 0; i < items; i++) { | |
dataLen = _itemLength(memPtr); | |
result[i] = RLPItem(dataLen, memPtr); | |
memPtr = memPtr + dataLen; | |
} | |
return result; | |
} | |
// @return indicator whether encoded payload is a list. negate this function call for isData. | |
function isList(RLPItem memory item) internal pure returns (bool) { | |
if (item.len == 0) return false; | |
uint8 byte0; | |
uint256 memPtr = item.memPtr; | |
assembly { | |
byte0 := byte(0, mload(memPtr)) | |
} | |
if (byte0 < LIST_SHORT_START) return false; | |
return true; | |
} | |
/** RLPItem conversions into data types **/ | |
// @returns raw rlp encoding in bytes | |
function toRlpBytes(RLPItem memory item) | |
internal | |
pure | |
returns (bytes memory) | |
{ | |
bytes memory result = new bytes(item.len); | |
if (result.length == 0) return result; | |
uint256 ptr; | |
assembly { | |
ptr := add(0x20, result) | |
} | |
copy(item.memPtr, ptr, item.len); | |
return result; | |
} | |
// any non-zero byte is considered true | |
function toBoolean(RLPItem memory item) internal pure returns (bool) { | |
require(item.len == 1); | |
uint256 result; | |
uint256 memPtr = item.memPtr; | |
assembly { | |
result := byte(0, mload(memPtr)) | |
} | |
return result == 0 ? false : true; | |
} | |
function toAddress(RLPItem memory item) internal pure returns (address) { | |
// 1 byte for the length prefix | |
require(item.len == 21); | |
return address(toUint(item)); | |
} | |
function toUint(RLPItem memory item) internal pure returns (uint256) { | |
require(item.len > 0 && item.len <= 33); | |
uint256 offset = _payloadOffset(item.memPtr); | |
uint256 len = item.len - offset; | |
uint256 result; | |
uint256 memPtr = item.memPtr + offset; | |
assembly { | |
result := mload(memPtr) | |
// shfit to the correct location if neccesary | |
if lt(len, 32) { | |
result := div(result, exp(256, sub(32, len))) | |
} | |
} | |
return result; | |
} | |
// enforces 32 byte length | |
function toUintStrict(RLPItem memory item) internal pure returns (uint256) { | |
// one byte prefix | |
require(item.len == 33); | |
uint256 result; | |
uint256 memPtr = item.memPtr + 1; | |
assembly { | |
result := mload(memPtr) | |
} | |
return result; | |
} | |
function toBytes(RLPItem memory item) internal pure returns (bytes memory) { | |
require(item.len > 0); | |
uint256 offset = _payloadOffset(item.memPtr); | |
uint256 len = item.len - offset; // data length | |
bytes memory result = new bytes(len); | |
uint256 destPtr; | |
assembly { | |
destPtr := add(0x20, result) | |
} | |
copy(item.memPtr + offset, destPtr, len); | |
return result; | |
} | |
/* | |
* Private Helpers | |
*/ | |
// @return number of payload items inside an encoded list. | |
function numItems(RLPItem memory item) private pure returns (uint256) { | |
if (item.len == 0) return 0; | |
uint256 count = 0; | |
uint256 currPtr = item.memPtr + _payloadOffset(item.memPtr); | |
uint256 endPtr = item.memPtr + item.len; | |
while (currPtr < endPtr) { | |
currPtr = currPtr + _itemLength(currPtr); // skip over an item | |
count++; | |
} | |
return count; | |
} | |
// @return entire rlp item byte length | |
function _itemLength(uint256 memPtr) private pure returns (uint256) { | |
uint256 itemLen; | |
uint256 byte0; | |
assembly { | |
byte0 := byte(0, mload(memPtr)) | |
} | |
if (byte0 < STRING_SHORT_START) itemLen = 1; | |
else if (byte0 < STRING_LONG_START) | |
itemLen = byte0 - STRING_SHORT_START + 1; | |
else if (byte0 < LIST_SHORT_START) { | |
assembly { | |
let byteLen := sub(byte0, 0xb7) // # of bytes the actual length is | |
memPtr := add(memPtr, 1) // skip over the first byte | |
/* 32 byte word size */ | |
let dataLen := div(mload(memPtr), exp(256, sub(32, byteLen))) // right shifting to get the len | |
itemLen := add(dataLen, add(byteLen, 1)) | |
} | |
} else if (byte0 < LIST_LONG_START) { | |
itemLen = byte0 - LIST_SHORT_START + 1; | |
} else { | |
assembly { | |
let byteLen := sub(byte0, 0xf7) | |
memPtr := add(memPtr, 1) | |
let dataLen := div(mload(memPtr), exp(256, sub(32, byteLen))) // right shifting to the correct length | |
itemLen := add(dataLen, add(byteLen, 1)) | |
} | |
} | |
return itemLen; | |
} | |
// @return number of bytes until the data | |
function _payloadOffset(uint256 memPtr) private pure returns (uint256) { | |
uint256 byte0; | |
assembly { | |
byte0 := byte(0, mload(memPtr)) | |
} | |
if (byte0 < STRING_SHORT_START) return 0; | |
else if ( | |
byte0 < STRING_LONG_START || | |
(byte0 >= LIST_SHORT_START && byte0 < LIST_LONG_START) | |
) return 1; | |
else if (byte0 < LIST_SHORT_START) | |
// being explicit | |
return byte0 - (STRING_LONG_START - 1) + 1; | |
else return byte0 - (LIST_LONG_START - 1) + 1; | |
} | |
/* | |
* @param src Pointer to source | |
* @param dest Pointer to destination | |
* @param len Amount of memory to copy from the source | |
*/ | |
function copy( | |
uint256 src, | |
uint256 dest, | |
uint256 len | |
) private pure { | |
if (len == 0) return; | |
// copy as many word sizes as possible | |
for (; len >= WORD_SIZE; len -= WORD_SIZE) { | |
assembly { | |
mstore(dest, mload(src)) | |
} | |
src += WORD_SIZE; | |
dest += WORD_SIZE; | |
} | |
// left over bytes. Mask is used to remove unwanted bytes from the word | |
uint256 mask = 256**(WORD_SIZE - len) - 1; | |
assembly { | |
let srcpart := and(mload(src), not(mask)) // zero out src | |
let destpart := and(mload(dest), mask) // retrieve the bytes | |
mstore(dest, or(destpart, srcpart)) | |
} | |
} | |
} | |
/// @title Token predicate interface for all pos portal predicates | |
/// @notice Abstract interface that defines methods for custom predicates | |
interface ITokenPredicate { | |
/** | |
* @notice Deposit tokens into pos portal | |
* @dev When `depositor` deposits tokens into pos portal, tokens get locked into predicate contract. | |
* @param depositor Address who wants to deposit tokens | |
* @param depositReceiver Address (address) who wants to receive tokens on side chain | |
* @param rootToken Token which gets deposited | |
* @param depositData Extra data for deposit (amount for ERC20, token id for ERC721 etc.) [ABI encoded] | |
*/ | |
function lockTokens( | |
address depositor, | |
address depositReceiver, | |
address rootToken, | |
bytes calldata depositData | |
) external returns(address, address, bytes memory); | |
/** | |
* @notice Validates and processes exit while withdraw process | |
* @dev Validates exit log emitted on sidechain. Reverts if validation fails. | |
* @dev Processes withdraw based on custom logic. Example: transfer ERC20/ERC721, mint ERC721 if mintable withdraw | |
* @param withdrawer Address who wants to withdraw tokens | |
* @param rootToken Token which gets withdrawn | |
* @param logRLPList Valid sidechain log for data like amount, token id etc. | |
*/ | |
function exitTokens( | |
address withdrawer, | |
address rootToken, | |
bytes calldata logRLPList | |
) external; | |
} | |
contract Initializable { | |
bool inited = false; | |
modifier initializer() { | |
require(!inited, "already inited"); | |
inited = true; | |
_; | |
} | |
} | |
interface Data { | |
function setTest(uint _test) external; | |
} | |
contract CustomPredicate is ITokenPredicate, AccessControlMixin, Initializable { | |
using RLPReader for bytes; | |
using RLPReader for RLPReader.RLPItem; | |
bytes32 public constant MANAGER_ROLE = keccak256("MANAGER_ROLE"); | |
bytes32 public constant CUSTOM_EVENT_SIG = 0xb7e5ddf32ab01f4630c5cf14dac344aba9e35bc5d91d1aa31c55f13c19094913; | |
event LockedERC20( | |
address indexed depositor, | |
address indexed depositReceiver, | |
address indexed rootToken, | |
uint256 amount | |
); | |
constructor() public {} | |
function initialize(address _owner) external initializer { | |
_setupContractId("CustomPredicate"); | |
_setupRole(DEFAULT_ADMIN_ROLE, _owner); | |
_setupRole(MANAGER_ROLE, _owner); | |
} | |
function exitTokens( | |
address withdrawer, | |
address rootToken, | |
bytes memory log | |
) | |
public | |
override | |
only(MANAGER_ROLE) | |
{ | |
RLPReader.RLPItem[] memory logRLPList = log.toRlpItem().toList(); | |
RLPReader.RLPItem[] memory logTopicRLPList = logRLPList[1].toList(); // topics | |
require( | |
bytes32(logTopicRLPList[0].toUint()) == CUSTOM_EVENT_SIG, // topic0 is event sig | |
"CustomPredicate: INVALID_SIGNATURE" | |
); | |
Data(rootToken).setTest( | |
logRLPList[2].toUint() // log data field | |
); | |
} | |
function lockTokens( | |
address depositor, | |
address depositReceiver, | |
address rootToken, | |
bytes calldata depositData | |
) | |
external | |
override | |
only(MANAGER_ROLE) | |
returns(address, address, bytes memory) | |
{ | |
revert("Disabled feature"); | |
} | |
} |
Sign up for free
to join this conversation on GitHub.
Already have an account?
Sign in to comment