noaccept.fif

"Asm.fif" include
"TonUtil.fif" include

<{
  DUP -1 INT EQUAL <{
    2DROP
    PUSHROOT CTOS 32 PLDU
    DUP 5 INT LEQ <{
      ACCEPT
    }> PUSHCONT IF
    INC
    NEWC 32 STU ENDC POPROOT
  }> PUSHCONT IFJMP

  DUP 85143 INT EQUAL <{
    DROP
    PUSHROOT CTOS 32 PLDU
  }> PUSHCONT IFJMP
}>c constant code
<b 0 32 u, b> constant data
<b b> <s constant msg

<b b{0011} s, code ref, data ref, dictnew dict, b> constant stateinit
0 stateinit hashu 2constant address

<b b{1000100} s, address addr, b{000010} s, stateinit <s s, b{0} s, msg s, b>
  2 boc+>B "noaccept-new.boc" B>file
<b b{1000100} s, address addr, 0 Gram, b{00} s, msg s, b>
  2 boc+>B "noaccept-query.boc" B>file

"lite-client -c 'last' -c 'getaccount " type address 7 smca>$ type "'" type cr
"lite-client -c 'last' -c 'runmethod " type address 7 smca>$ type " seqno'" type cr
"lite-client -c 'sendfile noaccept-new.boc'" type cr
"lite-client -c 'sendfile noaccept-query.boc'" type cr

// lite-client -c 'last' -c 'getaccount 0QCWGYmwSQbizeesBiMQm8nnPq4PlZTMfb9_Q-jj9A1neKpy'
// lite-client -c 'last' -c 'runmethod 0QCWGYmwSQbizeesBiMQm8nnPq4PlZTMfb9_Q-jj9A1neKpy seqno'
// lite-client -c 'sendfile noaccept-new.boc'
// lite-client -c 'sendfile noaccept-query.boc'
// */