PKGBUILD

# Maintainer: Raku <raku at raku dot party>

_pkgname="remoteplaywhatever"
pkgname=${_pkgname}-git
pkgver=r40.3cb7d22
pkgrel=1
pkgdesc='Tiny application that lets you force remote play together any game you have in your steam library including non-steam ones.'
arch=(x86_64)
url='https://github.com/m4dEngi/RemotePlayWhatever'
license=('MIT')
source=("${_pkgname}::git+https://github.com/m4dEngi/RemotePlayWhatever")
conflicts=("${_pkgname}" 'remoteplaywhatever-bin')
provides=(remopteplaywhatever)
sha256sums=('SKIP')


pkgver() {
  cd "$_pkgname"
  ( set -o pipefail
    git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  )
}


prepare() {
    cd "$srcdir"/"${_pkgname}"
    git submodule init
    git submodule update
}

build() {
    cmake -B build -S "$_pkgname" \
        -DCMAKE_BUILD_TYPE='None' \
        -DCMAKE_INSTALL_PREFIX='/usr' \
        -Wno-dev
    cmake --build build
}

package() {
    DESTDIR="$pkgdir" cmake --install build
}