gistfile1.txt

plugins {
    id 'org.spongepowered.plugin' version '0.7'
    id 'com.github.johnrengelman.shadow' version '1.2.3'
}

apply from: "GradleCommon/common.gradle"

defaultTasks 'clean', 'updateLicenses', 'build'

group = 'net.caseif.flint.inferno'
version = '1.3.1'

// Extended project information
ext.projectName = 'inferno'
ext.description = 'The implementation of Flint minigame framework for the Sponge Minecraft server mod.'
ext.inceptionYear = '2016'
ext.packaging = 'jar'

configurations {
    shadow
    compile {
        extendsFrom shadow
    }
}

repositories {
    maven {
        name 'caseif'
        url 'http://repo.caseif.net/content/groups/public/'
    }
    maven {
        name 'sponge'
        url 'https://repo.spongepowered.org/maven/'
    }
}

dependencies {
    compile 'org.spongepowered:spongeapi:5.1.0-SNAPSHOT'
    shadow project(":common")
    //shadow 'net.minecrell.mcstats:statslite-sponge:0.2.2'
}

// Read source files using UTF-8
tasks.withType(org.gradle.api.tasks.compile.JavaCompile) {
    options.encoding = 'UTF-8'
}

jar {
    classifier = 'base'
}

processResources {
    from 'LICENSE.txt'
}

shadowJar {
    configurations = [project.configurations.shadow]
    classifier = ''

    dependencies {
        include dependency('net.caseif.flint.common:flintcommon')
        include dependency('net.minecrell.mcstats:statslite-sponge')
    }

    relocate 'net.minecrell.mcstats', 'net.caseif.flint.inferno.lib.net.minecrell.mcstats'
}

task sourceJar(type: Jar) {
    from sourceSets.main.java
    from sourceSets.main.resources
    classifier = 'sources'
}

artifacts {
    archives shadowJar
    archives sourceJar
}

task wrapper(type: Wrapper) {
    gradleVersion = '3.0'
}