libfm-qt double click patched PKGBUILD

PKGBUILD

_pkgname=libfm-qt
pkgname=${_pkgname}
pkgver=0.15.1
pkgrel=1
pkgdesc="Qt port of libfm, a library providing components to build desktop file managers"
arch=("i686" "x86_64")
url="https://github.com/lxqt/libfm-qt"
license=("LGPL")
depends=("qt5-x11extras" "menu-cache" "libexif")
makedepends=("cmake" "qt5-tools" "lxqt-build-tools")
optdepends=(
  "gvfs: support for the trash bin and network devices"
)
provides=("${_pkgname}")
provides+=(libfm-qt.so)
conflicts=("${_pkgname}")
source=(
    "https://github.com/lxqt/libfm-qt/archive/${pkgver}.tar.gz"
    "libfm-qt-pr549.patch::https://github.com/lxqt/libfm-qt/pull/549.patch"
)
sha512sums=(
    "36e4cd0d0d86ced842c8aba690f8b28bfd0a1ae1ab817eb8c73f50a96db13945e634987284fbbe264e29ed28bd97850c2c8911c81c76c6adaf7ee4357f9695b3"
    "f5a49a74ba84f07c38a9ea52da6cc1c6b5068cb3bdf01396153a5c80daaca062a96623151e27ce40274dbfe186fdd069ba228ce747ae6475d25612dc708e16e5"
)
prepare() {
  mkdir -p build
  cd "${_pkgname}-${pkgver}"
  patch --forward --strip=1 --input="${srcdir}/libfm-qt-pr549.patch"
}
build() {
  cd build
  cmake \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    ../"${_pkgname}-${pkgver}"
  make
}
package() {
  cd build
  make DESTDIR="${pkgdir}" install

  # CMake installs empty folders unexpectedly
  # https://gitlab.kitware.com/cmake/cmake/issues/17122
  rmdir "${pkgdir}"/usr/include/libfm-qt/{tests,translations}
}