mutter 3.29.1 w/ patches for Arch

PKGBUILD

# $Id$
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Maintainer: Ionut Biru <ibiru@archlinux.org>
# Contributor: Michael Kanis <mkanis_at_gmx_dot_de>

pkgname=mutter
pkgver=3.29.1
pkgrel=1
pkgdesc="A window manager for GNOME"
url="https://git.gnome.org/browse/mutter"
arch=(x86_64)
license=(GPL)
depends=(dconf gobject-introspection-runtime gsettings-desktop-schemas libcanberra
         startup-notification zenity libsm gnome-desktop upower libxkbcommon-x11
         gnome-settings-daemon libgudev libinput pipewire)
makedepends=(intltool gobject-introspection git)
groups=(gnome)
_commit=b412e6c493feebab47fc4c23b03394a86e6dc165  # tags/3.29.1^0
source=("git+https://gitlab.gnome.org/GNOME/mutter.git#commit=$_commit"
        startup-notification.patch
        0001-compositor-Do-not-optimize-obscured-areas-away-in-pa.patch
        0002-compositor-Add-get_paint_volume-implementation-to-Me.patch
        0003-ClutterActor-Preserve-valid-paint-volumes-till-the-n.patch
        0008-clutter-Smooth-out-master-clock-to-smooth-visuals.patch
        0009-MetaShapedTexture-Disable-mipmapping-emulation.patch
        0010-WIP-backends-native-CRTCs-now-hold-references-to-fro.patch
        0011-Revert-bump-version.patch)
sha256sums=(SKIP
            SKIP
            SKIP
            SKIP
            SKIP
            SKIP
            SKIP
            SKIP
            SKIP)

prepare() {
  cd $pkgname

  # https://bugs.archlinux.org/task/51940
  for p in ../*.patch; do
    echo $p
    patch -Np1 -i ../$p ||:
  done

  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd $pkgname

  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
      --libexecdir=/usr/lib --disable-static \
      --disable-schemas-compile --enable-compile-warnings=minimum \
      --enable-gtk-doc --enable-egl-device --enable-remote-desktop

  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
  sed -e 's/ -shared / -Wl,-O1,--as-needed\0/g' \
      -i {.,cogl,clutter}/libtool

  make
}

package() {
  cd $pkgname
  make DESTDIR="$pkgdir" install
}