Adds src/test/groovy as test sources to all projects under the current directory

fixIntellijProject.groovy

import groovy.io.FileType
import groovy.util.slurpersupport.GPathResult
import groovy.xml.XmlUtil

def intellijFileVisitor = { File intellijFile ->
    def groovyDir = new File(intellijFile.parentFile, 'src/test/groovy')
    if (groovyDir.isDirectory() && groovyDir.list()?.size() > 0) {
        def module = new XmlSlurper().parse(intellijFile)
        GPathResult sources = module.component.content.sourceFolder
        def groovySources = sources.any { it.@url == 'file://$MODULE_DIR$/src/test/groovy' }
        if (groovySources) {
            println "${intellijFile.parentFile} is setup correctly"
        } else {
            println "Groovy tests are not marked as such in ${intellijFile.parentFile}. Fixing it."
            module.component.content.appendNode {
                sourceFolder(url: 'file://$MODULE_DIR$/src/test/groovy', isTestSource: true)
            }
            try {
                intellijFile.withWriter { writer ->
                    XmlUtil.serialize(module, writer)
                }
                println "Fixed!"
            } catch (e) {
                println "Could not fix ${intellijFile}: $e"
            }
        }
    }
}

new File('.').traverse(type: FileType.FILES, nameFilter: ~/.*\.iml/, visit: intellijFileVisitor)