PKGBUILD For Package gatemate-p_r-bin

p_r

#!/bin/sh
exec /opt/gatemate/p_r/p_r "$@"

PKGBUILD

# Maintainer: rewby <rewby@protonmail.com>
pkgname=gatemate-p_r-bin
pkgver=r2024.02.001
pkgrel=1
pkgdesc="The place and route tool for CologneChip GateMate FPGA chips."
arch=('x86_64')
url="https://colognechip.com/programmable-logic/gatemate/gatemate-download/"
license=('unknown')
depends=(bash gcc-libs zlib glibc)
source=("https://colognechip.com/downloads/cc-toolchain-linux.tar.gz"
	"p_r")
sha256sums=('SKIP'
            '69c5ad488baa77c4ff2bad74a922feb338781915fa27bebeaa2b3e75a41e51d2')

pkgver() {
	cd "${srcdir}/cc-toolchain-linux/bin"
	grep p_r VERSION | sed 's/\r//g;s/p_r-dcclinux64-\(.*\)/r\1/g;s/-/./g'
}

package() {
	install -D -m755 "p_r" -t "${pkgdir}/usr/bin"
	cd "${srcdir}/cc-toolchain-linux/bin/p_r"
	for file in cc_best_eco_dly.dly \
		cc_best_lpr_dly.dly \
		cc_best_spd_dly.dly \
		cc_typ_eco_dly.dly \
		cc_typ_lpr_dly.dly \
		cc_typ_spd_dly.dly \
		cc_worst_eco_dly.dly \
		cc_worst_lpr_dly.dly \
		cc_worst_spd_dly.dly \
		cpelib.v; do
		install -D -m644 "$file" -t "${pkgdir}/opt/gatemate/p_r"
	done
	install -D -m755 "p_r" -t "${pkgdir}/opt/gatemate/p_r"

}