Jenksfile declarative pipeline with parallel dynamic stages

Jenkinsfile

def applications = env.APPLICATIONS.split(",").findAll { it }.collect { it.trim() }
def environment  = env.ENVIRONMENT
def version      = env.VERSION
def jobs         = [:]

if (applications.size() < 1) {
    error("ERROR: APPLICATIONS must be a comma-delimited list of applications to build")
}

for (int i = 0; i < applications.size(); i++) {
    def app = applications[i]
    jobs["jobs-${app}"] = {
        node {
            stage("Build ${app}") {
                build job: 'Application-Builder', parameters: [
                    string(name: 'APPLICATION', value: app),
                    string(name: 'ENVIRONMENT', value: environment),
                    string(name: 'VERSION',     value: version)
                ]
            }
        }
    }
}

pipeline {
    agent none
    stages {
        stage('Build apps(s)') {
            steps {
                script {
                    parallel jobs
                }
            }
        }
    }
}

well written parallel dynamically load stages 👍

copy pasted, thank you 👍

Great example! Thanks kindly. 👍

Hi, in my verification the for loop doesn't work well with a closure.
See https://www.convalesco.org/notes/2020/05/26/parallel-stages-in-jenkins-scripted-pipelines.html
Better use "each" instead:

applications.each { app ->
    jobs["jobs-${app}"] = {
        node {
            stage("Build ${app}") {
                build job: 'Application-Builder', parameters: [
                    string(name: 'APPLICATION', value: app),
                    string(name: 'ENVIRONMENT', value: environment),
                    string(name: 'VERSION',     value: version)
                ]
            }
        }
    }
}