PKGBUILD

libhighscore-libmgba

# Maintainer: Rijnder Wever <rijnder.wever at gmail.com>

_pkgname=libhighscore-mgba
pkgname="${_pkgname}"-git
pkgver=r8363.5af72a19e
pkgrel=1
pkgdesc="Nintendo Game Boy Advance libhighscore core"
arch=('x86_64')
url="https://github.com/alice-mkh/mgba"
license=('custom:MPL2')
depends=('libhighscore')
makedepends=('git' 'cmake')
provides=("${_pkgname}" 'libmGBA-highscore.so')
source=('git+https://github.com/alice-mkh/mgba.git')
md5sums=('SKIP')
_gitname="mgba"

pkgver() {
  cd "${_gitname}"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
  cd "${_gitname}"

  # source: https://gitlab.gnome.org/World/highscore/-/blob/main/flatpak/cores/mgba.json
  local cmake_args=(
    -B build
    -Wno-dev
    -DUSE_DEBUGGERS=OFF
    -DUSE_EDITLINE=OFF 
    -DUSE_GDB_STUB=OFF
    -DUSE_ZLIB=OFF
    -DUSE_MINIZIP=OFF
    -DUSE_PNG=OFF
    -DUSE_LIBZIP=OFF
    -DUSE_SQLITE3=OFF
    -DUSE_ELF=OFF
    -DUSE_LUA=OFF
    -DUSE_JSON_C=OFF
    -DUSE_LZMA=OFF
    -DUSE_DISCORD_RPC=OFF
    -DENABLE_SCRIPTING=OFF
    -DBUILD_QT=OFF
    -DBUILD_SDL=OFF
    -DBUILD_HIGHSCORE=ON
    -DSKIP_LIBRARY=ON
    -DCMAKE_BUILD_TYPE=Release
  )

  cmake "${cmake_args[@]}"
  cmake --build build
}

package() {
  cd "${_gitname}"
  
  install -Dm 755 build/libmGBA-highscore.so -t "${pkgdir}"/usr/lib/highscore/cores/
  install -Dm 644 LICENSE -t "${pkgdir}"/usr/share/licenses/"${_pkgname}"/
}

# vim: ts=2 sw=2 et: