fd-git PKGBUILD

# Maintainer: Rijnder Wever <rien334@gmail.com>

pkgname='fd-git'
pkgver=7.4.0.r3.gd48aeda
pkgrel=1
pkgdesc="Simple, fast and user-friendly alternative to find"
arch=('x86_64')
url='https://github.com/sharkdp/fd'
license=('MIT' 'APACHE')
depends=('gcc-libs')
makedepends=('git' 'rust')
provides=('fd')
conflicts=('fd' 'fd-rs-git')
source=("$pkgname::git+https://github.com/sharkdp/fd.git")
sha256sums=('SKIP')

pkgver() {
  cd "${pkgname}"
  git describe --long --tags \
    | sed 's/v//g;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "${pkgname}"
  cargo build --release
}

check() {
  cd "${pkgname}"
  cargo test --release
}

package() {
  cd "${pkgname}"
  install -Dm755 target/release/fd "$pkgdir"/usr/bin/fd
  install -Dm644 target/release/build/fd-find-*/out/fd.bash "$pkgdir"/usr/share/bash-completion/completions/fd
  install -Dm644 target/release/build/fd-find-*/out/fd.fish "$pkgdir"/usr/share/fish/vendor_completions.d/fd.fish
  install -Dm644 target/release/build/fd-find-*/out/_fd "$pkgdir"/usr/share/zsh/site-functions/_fd
  install -Dm644 doc/fd.1 "$pkgdir"/usr/share/man/man1/fd.1
  install -Dm644 LICENSE-APACHE "$pkgdir"/usr/share/licenses/fd/LICENSE-APACHE
  install -Dm644 LICENSE-MIT "$pkgdir"/usr/share/licenses/fd/LICENSE-MIT
}

# vim: ts=2 sw=2 et: