Good and bad solutions to a simple Jasmine spec

Bad Solution

class Picture

  setHeight: (height) ->
    @width = 400
    @height = 200
    
  setWidth: (width) ->
    @height = 50
    @width = 100

Example Spec

describe "A picture", ->

  beforeEach ->
    @picture = new Picture(width: 200, height: 100)


  describe "when its height is changed", ->
    beforeEach -> @picture.setHeight 200

    it "maintains its proportions", ->
      expect(@picture.width).toEqual 400
      expect(@picture.height).toEqual 200

  describe "when its width is changed", ->
    beforeEach -> @picture.setWidth 100

    it "maintains its proportions", ->
      expect(@picture.width).toEqual 100
      expect(@picture.height).toEqual 50

Good Solution

class Picture
  
  constructor: (options) ->
    @width = options.width
    @height = options.height
  
  proportions: ->
    @width / @height
  
  setHeight: (height) ->
    @width = height * @proportions()
    @height = height
    
  setWidth: (width) ->
    @height = width / @proportions()
    @width = width