AWS API Gateway with greedy path (proxy+) calling httpbin. (Terraform)

apigateway.tf

resource "aws_api_gateway_rest_api" "MyDemoAWSAPI" {
  name        = "MyDemoAWSAPI"
  description = "This is my API for demonstration purposes"
}

resource "aws_api_gateway_resource" "MyDemoResource" {
  rest_api_id = aws_api_gateway_rest_api.MyDemoAWSAPI.id
  parent_id   = aws_api_gateway_rest_api.MyDemoAWSAPI.root_resource_id
  path_part   = "{proxy+}"
}

resource "aws_api_gateway_method" "MyDemoMethod" {
  rest_api_id   = aws_api_gateway_rest_api.MyDemoAWSAPI.id
  resource_id   = aws_api_gateway_resource.MyDemoResource.id
  http_method   = "GET"
  authorization = "NONE"
   request_parameters = {
    "method.request.path.proxy" = true
  }
}


resource "aws_api_gateway_integration" "MyDemoIntegration" {
  rest_api_id          = aws_api_gateway_rest_api.MyDemoAWSAPI.id
  resource_id          = aws_api_gateway_resource.MyDemoResource.id
  http_method          = aws_api_gateway_method.MyDemoMethod.http_method
  type                 = "HTTP_PROXY"
  uri                  = "https://httpbin.org/anything/{proxy}"
  integration_http_method = "GET"

  cache_key_parameters = ["method.request.path.proxy"]

  timeout_milliseconds = 28000
  request_parameters = {
    "integration.request.path.proxy" = "method.request.path.proxy"
  }

}

resource "aws_api_gateway_deployment" "teststage" {
  depends_on = [
    aws_api_gateway_integration.MyDemoIntegration
  ]
  rest_api_id = aws_api_gateway_rest_api.MyDemoAWSAPI.id
  stage_name  = "test"
}