partitionzipwith.erl

partitionzipwith.erl

-module(partitionzipwith).
-export([partitionzipwith/3]).

%% @doc A combination of lists:partition/2 and lists:zipwith/3.
%% Given two lists of equal length, call Combine(X, Y) for each.
%% If it returns {true, T}, then T is added to Satisfying.
%% If it returns {false, F}, then F is added to NotSatisfying.
-spec partitionzipwith(Combine, List1, List2) ->
    {Satisfying, NotSatisfying}
      when
      Combine :: fun((X, Y) -> {true, T} | {false, F}),
        List1 :: [X], List2 :: [Y],
        Satisfying :: [T], NotSatisfying :: [F].
partitionzipwith(Combine, List1, List2) ->
    partitionzipwith(Combine, List1, List2, [], []).

partitionzipwith(_Combine, [], [], Satisfying, NotSatisfying) ->
    {lists:reverse(Satisfying), lists:reverse(NotSatisfying)};
partitionzipwith(Combine, [X | List1], [Y | List2], Satisfying, NotSatisfying) ->
    case Combine(X, Y) of
        {true, T} -> partitionzipwith(Combine, List1, List2, [T | Satisfying], NotSatisfying);
        {false, F} -> partitionzipwith(Combine, List1, List2, Satisfying, [F | NotSatisfying])
    end.