Debugging HTML 5 Application Cache

app_cache.js.coffee

# Application Cache Debugging and Handling
#
# Inspired by Jonathan Stark's Debugging HTML 5 Offline Application Cache
# http://jonathanstark.com/blog/2009/09/27/debugging-html-5-offline-application-cache/

cacheStatusValues = [
  "uncached"
  "idle"
  "checking"
  "downloading"
  "updateready"
  "obsolete"
]

if cache = window.applicationCache
  logEvent = (e) ->
    online = if (navigator.onLine) then "online" else "offline"
    status = cacheStatusValues[cache.status]
    type = e.type
    message = "Application Cache #{type} event (#{online}, #{status})"
    if (type == "error" && navigator.onLine)
      message+= " (probably a syntax error in manifest)"
    console.log(message)

  swapCache = ->
    try
      cache.swapCache()
      console.log("Swapped cache")
    catch error
      console.log("Couldn't swap cache", error)

  checkCache = ->
    try
      cache.update()
    catch error
      console.log("Couldn't update cache", error)

  checkCacheLater = ->
    setTimeout checkCache, 300000

  document.addEventListener "DOMContentLoaded", (->
    cache.addEventListener "checking",    logEvent, false
    cache.addEventListener "downloading", logEvent, false
    cache.addEventListener "progress",    logEvent, false
    cache.addEventListener "cached",      logEvent, false
    cache.addEventListener "updateready", logEvent, false
    cache.addEventListener "noupdate",    logEvent, false
    cache.addEventListener "error",       logEvent, false
    cache.addEventListener "obsolete",    logEvent, false

    cache.addEventListener "updateready", swapCache, false

    cache.addEventListener "cached",      checkCacheLater, false
    cache.addEventListener "noupdate",    checkCacheLater, false
    cache.addEventListener "updateready", checkCacheLater, false
    cache.addEventListener "error",       checkCacheLater, false
    cache.addEventListener "obsolete",    checkCacheLater, false
  ), false


# protection against accidental left-over console.log statements
window.console = { log: -> } unless window.console?