scan deps for updates

gistfile1.erl

#!/usr/bin/env escript

-mode(compile).

main(_) ->
    lists:foreach(fun({Dep, Vsn}) ->
        fetch_dep(Dep),
        show_dep(Dep, Vsn)
    end, load_deps()).


load_deps() ->
    {ok, Config} = file:consult(locate_rebar_config()),
    Deps = proplists:get_value(deps, Config),
    lists:sort(lists:flatmap(fun
        ({Dep, ".*", {git, _Url, Vsn}}) -> [{Dep, Vsn}];
        ({_, _, _, [raw]}) -> []
    end, Deps)).


fetch_dep(Dep) ->
    Cmd = [
        "cd ",
        dep_dir(Dep),
        "; git fetch origin"
    ],
    os:cmd(Cmd).


show_dep(Dep, Spec) ->
    Cmd = mk_cmd(Dep, Spec),
    Out = os:cmd(Cmd),
    Stripped = string:strip(Out),
    if Stripped == "" -> ok; true ->
        io:format("~s :: ~p~n", [Dep, Spec]),
        io:format("~s~n~n", [Out])
    end.

mk_cmd(Dep, {tag, Tag}) ->
    [
        "cd ",
        dep_dir(Dep),
        "; git log --format=\"%h %s\" ",
        Tag,
        "..origin/master"
    ];
mk_cmd(Dep, {branch, Branch}) ->
    [
        "cd ",
        dep_dir(Dep),
        "; git log --format=\"%h %s\" ",
        io_lib:format("~s", [Branch]),
        "..origin/master"
    ].


locate_rebar_config() ->
    filename:join(the_root(), "rebar.config").


dep_dir(Dep) ->
    filename:join([the_root(), "deps", atom_to_list(Dep)]).


the_root() ->
    ESName = escript:script_name(),
    AbsESName = filename:absname(ESName),
    filename:dirname(filename:dirname(AbsESName)).