Auto BCC the specified recipient on all sent emails in Outlook 2010.

outlook-macro-auto-bcc.vba

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    ' Auto BCC the specified recipient on all sent emails. See "settings" below
    '
    ' From "How to Automatically BCC in Outlook 2010" by Jack Bush, Nov. 2010
    ' <http://www.groovypost.com/howto/microsoft/how-to-automatically-bcc-in-outlook-2010/>
    
    Dim objRecip As Recipient
    Dim strMsg As String
    Dim res As Integer
    Dim BCC_ADDR As String
    On Error Resume Next
    
    ' Settings
    ' --------
    ' Address for BCC. Must be SMTP address, or resolvable to a name in the
    ' address book.
    BCC_ADDR = "user@domain"
    
    Set objRecip = Item.Recipients.Add(BCC_ADDR)
    objRecip.Type = olBCC
    If Not objRecip.Resolve Then
        strMsg = "Could not resolve the Bcc recipient. " & _
        "Do you want still to send the message?"
        res = MsgBox(strMsg, vbYesNo + vbDefaultButton1, _
        "Could Not Resolve Bcc Recipient")
        If res = vbNo Then
            Cancel = True
        End If
    End If
    
    Set objRecip = Nothing
End Sub