monitors the actual occupancy of a parking lot

free_parking_detector.ino

const int trigpin = 13; // select the pin for the 'trig' ultrasonic sensor
const int echopin = 12; // select the pin for the 'echo' ultrasonic sensor

const int redpin   = 11; // select the pin for the   red LED
const int greenpin = 10; // select the pin for the green LED
const int bluepin   = 9; // select the pin for the  blue LED

void setup () {
  // set ultrasonic sensor pin modes
  pinMode(trigpin, OUTPUT);
  pinMode(echopin, INPUT);

  // set LED pin modes
  pinMode (redpin, OUTPUT);
  pinMode (bluepin, OUTPUT);
  pinMode (greenpin, OUTPUT);

  // open serial port, set data rate to 9600 bps
  Serial.begin (9600);
}

void loop () {
    detectParkingFree();
}

void rgb(int r, int g, int b) {
   analogWrite(redpin,   r);
   analogWrite(greenpin, g);
   analogWrite(bluepin,  b);
}

float getDistance() {
  static const float v = 331.5 + 0.6 * 20; // m/s

  // send sound pulse
  digitalWrite(trigpin, LOW);
  delayMicroseconds(3);
  digitalWrite(trigpin, HIGH);
  delayMicroseconds(5);
  digitalWrite(trigpin, LOW);

  // listen for echo
  float pulse = pulseIn(echopin, HIGH);  // microseconds
  float t = pulse / 1000.0 / 1000.0 / 2; // seconds
  float d = t * v; // m

  return d * 100; // cm
}

void detectParkingFree() {
  // get distance to the vehicle below
  float distance = getDistance();

  // set color depending on the distance
  if (distance <= 10) {
    rgb(255, 0, 0); // red
  } else if (distance > 10 && distance <= 35) {
    rgb(255, 170, 0); // yellow
  } else {
    rgb(0, 255, 0); // green
  }
}