Deploy a Gradle Scala project to Maven Central, or any Maven repository for that matter, based upon the presence of variables in your gradle.properties file. Plays nicely with continuous integration tools like Travis-CI.

build.gradle

apply plugin: 'maven'
apply plugin: 'scala'
apply plugin: 'signing'

def isMavenDeployable = hasProperty('mavenRepositoryUrl') &&
	hasProperty('mavenRepositoryUsername') &&
	hasProperty('mavenRepositoryPassword')

if (isMavenDeployable) {
	signing {
		sign configurations.archives
	}

	task scaladocJar(type: Jar, dependsOn: scaladoc) {
		classifier = 'javadoc'
		from "${project.buildDir}/docs/scaladoc"
	}

	task sourceJar(type: Jar, dependsOn: classes) {
		classifier = 'sources'
		from sourceSets.main.allSource
	}

	artifacts {
		archives jar
		archives scaladocJar
		archives sourceJar
	}

	uploadArchives {
		repositories {
			mavenDeployer {
				beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

				repository(url: mavenRepositoryUrl) {
					authentication(userName: mavenRepositoryUsername, password: mavenRepositoryPassword)
				}

				pom.project {
					description "${parent.project.description}"
					groupId "${parent.project.group}"
					name "${project.name}"
					packaging 'jar'
					url "${parent.project.url}"
					version "${parent.project.version}"

					developers {
						developer {
							id 'rockymadden'
							name 'Rocky Madden'
						}
					}

					licenses {
						license {
							name 'Apache License v2.0'
							url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
							distribution 'repo'
						}
					}

					scm {
						url "${parent.project.scm}"
						connection "${parent.project.scm}"
					}
				}
			}
		}
	}
}

deploy.sh

$ gradle uploadArchives

gradle.properties

signing.keyId=
signing.password=
signing.secretKeyRingFile=

mavenRepositoryPassword=
mavenRepositoryUrl=https://oss.sonatype.org/service/local/staging/deploy/maven2/
mavenRepositoryUsername=

Thank you for this example !

For people who will come later, to generate the required keyring file:
gpg --export-secret-keys -o secring.gpg