Import users into Lightdash from Okta CSV dump (Clojure)

okta.csv

okta_lightdash.clj

(ns okta-lightdash
  (:require [clj-http.client :as http]
            [clojure.data.csv :as csv]
            [cheshire.core :as json]))

(def lightdash-host "lightdash-host")
(def api-key "api-key")

(def base (str "https://" lightdash-host "/api/v1"))

(defn req [method url params]
  (try
    (:body (http/request (merge params {:method method :url url})))
    (catch Exception e
      (prn (ex-info "request error" (some-> e ex-data :body json/decode) e)))))

(defn params [x]
  (-> {:headers      {:Authorization (str "ApiKey " api-key)}
       :content-type :json
       :as           :json}
      (assoc :form-params x)))

(defn create-invite [user]
  (->> (params {:expiresAt "2024-12-31T00:00:00Z" :email (:user.email user)})
       (req :post (str base "/invite-links"))
       :results
       :inviteCode))

(defn create-user [user invite-code]
  (->> (params {:inviteCode invite-code
                :firstName  (:user.firstName user)
                :lastName   (:user.lastName user)
                :email      (:user.email user)
                :password   (:user.id user)})
       (req :post (str base "/user"))))

(def users
  (let [data (csv/read-csv (slurp "okta.csv"))]
    (map (partial apply hash-map) (map (partial interleave (map keyword (first data))) (rest data)))))

(def active-users (filter (comp #(= "ACTIVE" %) :user.status) users))

(comment
  (for [user active-users]
    (let [invite-code (create-invite user)]
      (create-user user invite-code))))