PKGBUILD - pcsx2-git - 64 bit

# Maintainer: rafaelff <rafaelff@gnome.org>, WeirdBeard <obarrtimothy@gmail.com>
# Contributor: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Themaister <maister@archlinux.us>

pkgname=pcsx2-git
pkgver=1.7.0.r680.083380297
pkgrel=1
pkgdesc='A Sony PlayStation 2 emulator'
arch=(x86_64)
url=https://www.pcsx2.net
license=(
    GPL2
    GPL3
    LGPL2.1
    LGPL3
)
depends=(
    fmt
    libaio
    libjpeg-turbo
    libpcap
    libpulse
    libsamplerate
    portaudio
    sdl2
    soundtouch
    wxgtk3
)
makedepends=(
    cmake
    git
    ninja
    xorgproto
)
provides=(pcsx2)
conflicts=(pcsx2)
source=(git+https://github.com/PCSX2/pcsx2.git)
sha256sums=('SKIP')

pkgver() {
    cd pcsx2

    git describe --tags | sed 's/^v//; s/-dev//; s/-/.r/; s/-g/./'
}

prepare() {
    cd pcsx2/3rdparty

    git submodule update --init --recursive
}

build() {
    cmake -G Ninja -B build -S pcsx2 \
        -DCMAKE_BUILD_TYPE=Release \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DDOC_DIR=/usr/share/doc/pcsx2 \
        -DGAMEINDEX_DIR=/usr/share/pcsx2 \
        -DPLUGIN_DIR=/usr/lib/pcsx2 \
        -DDISABLE_BUILD_DATE=ON \
        -DDISABLE_PCSX2_WRAPPER=ON \
        -DEXTRA_PLUGINS=ON \
        -DSDL2_API=ON \
        -DPACKAGE_MODE=ON \
        -DREBUILD_SHADER=ON \
        -DUSE_LTO=ON \
        -DUSE_VTUNE=OFF \
        -DXDG_STD=ON \
        -DwxWidgets_CONFIG_EXECUTABLE=/usr/bin/wx-config-gtk3 \
        -Wno-dev

    cmake --build build
}

package() {
    DESTDIR="${pkgdir}" cmake --install build
}