Transform ISC leases to dnsmasq file format.

transform_leases.awk

#! /bin/awk -f
/^lease.*{/{
  lease = $2
  next
}
lease != "" {
  sub(/;$/,"")
  if (/^}/) {
    if (lease_["binding_state"] == "active") {
      cmd="date -u -d \"" gensub(/^[0-9]+/,"",1,lease_["ends"]) "\" +%s"
      cmd | getline end
      close(cmd)
      if ("client-hostname" in lease_) {
        cmd="echo " lease_["client-hostname"]
        cmd | getline name
        close(cmd)
      } else {
        name = "*"
      }
      if ("uid" in lease_) {
        cmd="echo $(printf '%b' " lease_["uid"] " | od -t x1 -A none) | tr \" \" :"
        cmd | getline uid
        close(cmd)
      } else {
        uid = "*"
      }
      printf("%d %s %s %s %s\n",end,lease_["hardware_ethernet"],lease,name,uid)
    }
    lease = ""
    delete lease_
  } else {
    i=1
    k = $i
    while ($i == "next" || $i == "binding" || $i == "hardware") {
      k = k "_" $(++i)
    }
    lease_[k] = $(++i)
    for (i++; i<=NF; i++) {
      lease_[k] = lease_[k] " " $i
    }
  }
}