Local Scopes - Examples showing local scopes in functions

Application.cfc

component {
	
}

component_local.cfc

component {

  function myFunc(){
    var myVar = "foo";
    echo(myVar); //outputs "foo"
  }
  
  function otherFunc(){
    echo(myVar); //errors for undefined variable
  }
  
}

component_local_struct.cfc

component {
	function myFunc(){
	  var myVar = "foo";
	  echo(local.myVar); //outputs foo
	}	
}

component_variables.cfc

component {

  function myFunc(){
    variables.myVar = "foo";
    echo(myVar); //outputs "foo"
  }
  
  function otherFunc(){
    echo(myVar); //outputs "foo";
    echo(variables.myVar); //same as above, outputs "foo" because myVar was in the variables scope which is global to this component
  }
  
}

localScopesTest.cfc

/**
* My xUnit Test
*/
component extends="testbox.system.BaseSpec"{
	
/*********************************** LIFE CYCLE Methods ***********************************/

	// executes before all test cases
	function beforeTests(){
	}

	// executes after all test cases
	function afterTests(){
	}

	// executes before every test case
	function setup( currentMethod ){
	}

	// executes after every test case
	function teardown( currentMethod ){
	}

/*********************************** TEST CASES BELOW ***********************************/
	
	// Remember that test cases MUST start or end with the keyword 'test'
	function localScopeTest(){
		var test = new component_local();
		savecontent variable="out"{
			test.myFunc();
		}
		expect(out).toBe("foo");
		expect(function(){test.otherfunc()}).toThrow();
	}

	function variablesScopeTest(){
		var test = new component_variables();
		savecontent variable="out"{
			test.myFunc();
		}
		expect(out).toBe("foo");

		savecontent variable="out"{
			test.otherFunc();
		}
		expect(out).toBe("foofoo");
	}

	function localStructTest(){
		var test = new component_local_struct();
		savecontent variable="out"{
			test.myFunc();
		}
		expect(out).toBe("foo");
	}
	
}