Lucee Properties Examples

basicComponent.cfc

component {
  
  public function init(){
  }
  
}

basicComponent.png

comparison.cfm

<cfscript>
writeDump(new basicComponent());
writeDump(new componentWithProperties());
writeDump(new componentWithPropertiesAccessor());
</cfscript>

componenentWithPropertiesOverride.png

componentPropertiesType.png

componentPropertiesWithDefault.png

componentWithProperties.cfc

component {
  
	property name='myValue';

	public function init(){
		return this;
	}
  
}

componentWithProperties.png

componentWithPropertiesAccessor.cfc

component accessors='true' {
  
	property name='myValue';

	public function init(){
		return this;
	}
  
}

componentWithPropertiesAccessor.png

componentWithPropertiesDefault.cfc

component accessors='true' {
  
	property name='myValue' default='test this is a default!';

	public function init(){
		return this;
	}

	public function getValue(){
		return variables.myValue;
	}
  
}

componentWithPropertiesMeta.png

componentWithPropertiesNoConstructor.cfc

component accessors='true' {
  
	property name='myValue' required='true';

}

componentWithPropertiesOverride.cfc

component accessors='true' {
  
	property name='myValue' setter='false';

	public function init(){
		variables.myValue = 'Hello!';
		return this;
	}
  
}

componentWithPropertiesRequired.cfc

component accessors='true' {
  
	property name='myValue' required='true'; //Required has no effect

	public function init(){
		return this;
	}
  
}

componentWithPropertiesType.cfc

component accessors='true' {
  
	property name='myValue' type='struct';

	public function init(){
		return this;
	}
  
}

componentWithPropertiesType.png

componentWithPropertyValidations.cfc

component accessors='true' {
  
	property name='myEmail' validate='email';
	property name='myString' validate='string' validateparams="{minLength=0, maxLength=5}";
	  
}

constructor_call_setter.cfm

<cfscript>
myComponent = new componentWithPropertiesNoConstructor(myValue:"Hello there!");
echo(myComponent.getMyValue());
myComponent = new componentWithPropertiesNoConstructor({myValue:"Hello there!"}); //Equivalent to the above
echo(myComponent.getMyValue());
myComponent = new componentWithPropertiesNoConstructor(argumentCollection={myValue:"Hello there!"}); //Equivalent to the above
echo(myComponent.getMyValue());
writeDump(now());
</cfscript>

propertiesTests.cfc

/**
* My xUnit Test
*/
component extends="testbox.system.BaseSpec"{
	
/*********************************** LIFE CYCLE Methods ***********************************/

	// executes before all test cases
	function beforeTests(){
	}

	// executes after all test cases
	function afterTests(){
	}

	// executes before every test case
	function setup( currentMethod ){
	}

	// executes after every test case
	function teardown( currentMethod ){
	}

/*********************************** TEST CASES BELOW ***********************************/
	
	// Remember that test cases MUST start or end with the keyword 'test'
	function checkAllSyntaxTest(){
		 var files = directoryList("");
		 
		 for(file IN files){
		 	if(file CONTAINS ".cfm" AND !file CONTAINS "use_validations"){
		 		include template="#getFileFromPath(file)#";
		 	}
		 }
	}

	function getDefaultValueTest(){

		var myObj = new componentWithPropertiesDefault();
		expect(myObj.getValue()).toBe("test this is a default!");

	}

	function validateParamsTest(){

		var myObj = new componentWithPropertyValidations(myEmail:"test@domain.com", myString:"hellothere");
		// myObj.setMyString("hellothere");
		writeDump(myObj);

	}

	function useValidationsTest(){
		expect(function(){include template="use_validations.cfm"}).toThrow();
	}
	
}

reflect_properties.cfm

<cfscript>
writeDump(getComponentMetaData("componentWithProperties"));
</cfscript>

reflection_properties.png

use_accessors.cfm

<cfscript>
myComponent = new componentWithPropertiesAccessor();
myComponent.setMyValue("Hello!");
echo(myComponent.getMyValue());
</cfscript>

use_default.cfm

<cfscript>
myComponent = new componentWithPropertiesDefault();
writeDump(myComponent);
echo(myComponent.getMyValue());
writeDump(myComponent.getValue());
</cfscript>

use_override.cfm

<cfscript>
myComponent = new componentWithPropertiesOverride();
writeDump(myComponent);
echo(myComponent.getMyValue());
//myComponent.setMyValue("Hello!"); //errors that function does not exist
</cfscript>

use_required.cfm

<cfscript>
myComponent = new componentWithPropertiesRequired({});
myComponent.setMyValue("Hello!");
echo(myComponent.getMyValue());
</cfscript>

use_type.cfm

<cfscript>
myComponent = new componentWithPropertiesType();
writeDump(myComponent);
// myComponent.setMyValue('test'); //Will throw an error for invalid type
echo(myComponent.getMyValue());
</cfscript>

use_validations.cfm

<cfscript>
myObj = new componentWithPropertyValidations();
myObj.setMyEmail("test@domain.com"); //works
myObj.setMyString("hello"); //works
myObj.setMyEmail("test"); //throws error for invalid email
myObj.setMyString("hello there!"); //Throws error for invalid string

//Validation of auto poplated members is currently broken see https://luceeserver.atlassian.net/browse/LDEV-816
myObj = new componentWithPropertyValidations(myEmail:"test", myString:"hello there!");
</cfscript>