Skip to content

Instantly share code, notes, and snippets.

Embed
What would you like to do?
Batch script for keeping an up-to-date local copy of the latest 32 and 64-bit continuous builds of OSVR RenderManager and OSVR Core
@echo off
rem By Ryan Pavlik, Sensics, Inc. <http://sensics.com/osvr>
rem Copyright 2015-2016 Sensics, Inc.
rem SPDX-License-Identifier: Apache-2.0
rem Put this in a directory of its own, preferably. It will create one file and two subdirectories.
rem Doesn't hurt to run it more often than there are builds: it won't re-download (though
rem it will harmlessly re-extract)
rem Requires that you have wget and 7za (the command line version of 7z) in your path.
rem Easiest way is to use chocolatey.org to run choco install -y wget 7zip.commandline
rem which will install both.
echo.
echo --- Retrieving latest 64-bit build
wget --timestamping http://resource.osvr.com/public_download/OSVR-Core/OSVR-Core-Snapshot-latest-64bit.7z
echo.
echo --- Extracting 64-bit build over old one
7za x -y -aoa OSVR-Core-Snapshot-latest-64bit.7z > NUL
echo.
echo --- Retrieving latest 32-bit build
wget --timestamping http://resource.osvr.com/public_download/OSVR-Core/OSVR-Core-Snapshot-latest-32bit.7z
echo.
echo --- Extracting 32-bit build over old one
7za x -y -aoa OSVR-Core-Snapshot-latest-32bit.7z > NUL
echo.
echo --- Retrieving version file
wget --timestamping http://resource.osvr.com/public_download/OSVR-Core/osvr-ver.txt
echo --- Current OSVR-Core version is:
echo "Overall" version:
type osvr-ver.txt
echo.
echo Detailed 32-bit build info:
call :showver OSVR-Core-Snapshot-latest-32bit
echo.
echo Detailed 64-bit build info:
call :showver OSVR-Core-Snapshot-latest-64bit
pause
goto :eof
:showver
setlocal
set /p COREVER=<%1\osvr-ver.txt
set /p LIBFUNCVER=<%1\libfunctionality-ver.txt
echo OSVR-Core version %COREVER%, libfunctionality version %LIBFUNCVER%
echo.
endlocal
goto :eof
@echo off
rem By Ryan Pavlik, Sensics, Inc. <http://sensics.com/osvr>
rem Copyright 2015-2016 Sensics, Inc.
rem SPDX-License-Identifier: Apache-2.0
rem Put this in a directory of its own, preferably. It will create one file and two subdirectories.
rem Doesn't hurt to run it more often than there are builds: it won't re-download (though
rem it will harmlessly re-extract)
rem Requires that you have wget and 7za (the command line version of 7z) in your path.
rem Easiest way is to use chocolatey.org to run choco install -y wget 7zip.commandline
rem which will install both.
echo.
echo --- Retrieving latest 64-bit build
wget --timestamping http://resource.osvr.com/public_download/rmci/OSVR-RenderManager-64-latest-ci.7z
echo.
echo --- Extracting 64-bit build over old one
7za x -y -aoa -orendermanager-64-latest-ci OSVR-RenderManager-64-latest-ci.7z > NUL
echo.
echo --- Retrieving latest 32-bit build
wget --timestamping http://resource.osvr.com/public_download/rmci/OSVR-RenderManager-32-latest-ci.7z
echo.
echo --- Extracting 32-bit build over old one
7za x -y -aoa -orendermanager-32-latest-ci OSVR-RenderManager-32-latest-ci.7z > NUL
echo.
echo --- Retrieving version file
wget --timestamping http://resource.osvr.com/public_download/rmci/rendermanager-ver.txt
echo --- Current RenderManager version is:
echo "Overall" version:
type rendermanager-ver.txt
echo.
echo Detailed 32-bit build info:
call :showver rendermanager-32-latest-ci
echo.
echo Detailed 64-bit build info:
call :showver rendermanager-64-latest-ci
pause
goto :eof
:showver
setlocal
set /p RMVER=<%1\rendermanager-ver.txt
set /p COREVER=<%1\osvr-ver.txt
echo OSVR-RenderManager %RMVER% built against OSVR-Core version %COREVER%
echo.
endlocal
goto :eof
Sign up for free to join this conversation on GitHub. Already have an account? Sign in to comment
You can’t perform that action at this time.