PKGBUILD

# Maintainer: Sergey Shatunov <me@prok.pw>
pkgname=zram-generator
pkgver=0.3.1
pkgrel=1
pkgdesc="Systemd unit generator for zram devices"
arch=("x86_64")
url="https://github.com/systemd/zram-generator"
license=('MIT')
depends=("systemd")
makedepends=('rust' 'ruby-ronn-ng')
install='zram-generator.install'
source=("https://github.com/systemd/zram-generator/archive/v${pkgver}.tar.gz"
        'half-memory.conf.example'
        'zram-generator.install')
sha256sums=('c11acbd29780973aff542c41ff00d62c89d8f4ac493a9a6e844cf4187cf3c268'
            '1aa3e7a47303c0b2dff6d74cc569c12e8009ed4642301db67fb389cb313141cf'
            '17f510e96f763d1c9aa8c0de757ad38dbe089465fb802e3c34682793f060bf77')

build() {
        cd "$srcdir/${pkgname}-${pkgver}"
        make
}

check() {
        cd "$srcdir/${pkgname}-${pkgver}"
        make check
}

package() {
        cd "$srcdir/${pkgname}-${pkgver}"
        make DESTDIR="$pkgdir" install
        install -Dpm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
        install -Dpm644 "$srcdir/half-memory.conf.example" "$pkgdir/usr/share/doc/zram-generator/half-memory.conf.example"
}