creating member account connectors with terraform

accounts.csv

csv.tf

terraform {
  required_providers {
    harness = {
      source = "harness/harness"
    }
  }
}

# CSV Example

locals {
  # pull in accounts csv
  accounts_raw = csvdecode(file("./accounts.csv"))
  # only get linked account (ignore masters)
  accounts = [for account in local.accounts_raw : account if account["Type"] == "Linked Account"]
}

resource "harness_platform_connector_awscc" "csv" {
  for_each = { for account in local.accounts : "${trimspace(account["Linked account name"])}" => account }

  identifier = replace(trimspace(each.value["Linked account"]), "-", "_")
  name       = replace(trimspace(each.value["Linked account"]), "-", "_")

  account_id = trimspace(each.value["Linked account name"])
  features_enabled = [
    "OPTIMIZATION",
    "VISIBILITY",
    "GOVERNANCE",
  ]
  cross_account_access {
    role_arn    = "arn:aws:iam::${trimspace(each.value["Linked account name"])}:role/HarnessCERole"
    external_id = "harness:891928451355:qwerty"
  }
}

data.tf

terraform {
  required_providers {
    harness = {
      source = "harness/harness"
    }
  }
}

# AWS Data Source Example

data "aws_organizations_organization" "this" {}

resource "harness_platform_connector_awscc" "data" {
  for_each = { for account in data.aws_organizations_organization.this.accounts : "${trimspace(account.name)}" => account }

  identifier = replace(replace(trimspace(each.value.name), "-", "_"), " ", "_")
  name       = replace(replace(trimspace(each.value.name), "-", "_"), " ", "_")

  account_id = trimspace(each.value.id)
  features_enabled = [
    "OPTIMIZATION",
    "VISIBILITY",
    "GOVERNANCE",
  ]
  cross_account_access {
    role_arn    = "arn:aws:iam::${trimspace(each.value.id)}:role/HarnessCERole"
    external_id = "harness:891928451355:qwerty"
  }
}