game_process.coffee

Game = require '../models/game'

game = null

sendGameUpdate = (game)->
  process.send
    type: 'game'
    game: game.toJSON()

sendGameStop = (game)->
  process.send
    type: 'stop'
    name: game.name

createGame = (attributes)->
  game = new Game(attributes)
  game.addListener 'game', sendGameUpdate
  game.addListener 'stopped', sendGameStop
  game.start()
  game

process.on 'message', (event)->
  switch event.type
    when 'init'
      createGame(event.game)
    when 'addCycle'
      (game.width = event.game.width) if game.width > event.game.width
      (game.height = event.game.height) if game.height > event.game.height
      if (cycle = game.addCycle())?
        process.send
          type: 'cycleAdded'
          id: event.id
          cycleNumber: cycle.number
          game: game.toJSON()
      else
        process.send
          type: 'addCycleFailed'
          id: event.id
          name: event.game.name
    when 'removeCycle'
      game.removeCycle event.cycleNumber
    when 'movement'
      game.moveCycle event.cycleNumber, event.movement