Learning geb!

geb.groovy

import geb.Browser
import geb.Page
import geb.Module

class NavigationLink extends Module {
	
	def linkText

	static content = {
		link { $("a", text: linkText) }
	}

}

class NavigationBar extends Module {
	
	static content = {
		homeLink { module NavigationLink, linkText: "Home" }
		archiveLink { module NavigationLink, linkText: "Archives" }
		aboutLink { module NavigationLink, linkText: "About" }
	}

}

class SwalshPage extends Page {
	
	static content = {
		navBar { module NavigationBar }
	}

}

class HomePage extends SwalshPage {
	
	static url = "http://swalsh.org"
	static at = { title == "Sean Walsh" }

}

class ArchivesPage extends SwalshPage {
	
	static url = "http://swalsh.org/archives"
	static at = { title == "Blog Archive - Sean Walsh" }

}

class AboutPage extends SwalshPage {
	
	static url = "http://swalsh.org/about"
	static at = { title == "About - Sean Walsh" }

}

Browser.drive {

	to HomePage
	assert at( HomePage )

	navBar.archiveLink.link.click()
	assert at( ArchivesPage )

	navBar.aboutLink.link.click()
	assert at( AboutPage )

}