CMake: add target for invoking Clang Static Analyzer

clang_static_analysis.cmake

# The solution is based upon this answer:
# https://stackoverflow.com/questions/19050461/cmake-add-target-for-invoking-clang-analyzer
function(add_clang_static_analysis target)
    get_target_property(SRCs ${target} SOURCES)
    add_library(${target}_analyze OBJECT EXCLUDE_FROM_ALL ${SRCs})
    if (MSVC)
        list(APPEND ANALYZER_OPTIONS --analyze)
        list(APPEND ANALYZER_OPTIONS "SHELL:/clang:-Xanalyzer /clang:-analyzer-opt-analyze-headers")
        list(APPEND ANALYZER_OPTIONS "SHELL:/clang:-Xanalyzer /clang:-analyzer-output=html")
        # see output in <build/<file>.plist directories
    else()
        list(APPEND ANALYZER_OPTIONS --analyze)
        list(APPEND ANALYZER_OPTIONS "SHELL:-Xanalyzer -analyzer-opt-analyze-headers")
        list(APPEND ANALYZER_OPTIONS "SHELL:-Xanalyzer -analyzer-output=html")
        # see output in <build>/<tree>/CMakeFiles/<target>.dir/<file>.obj directories
    endif(MSVC)

    set_target_properties(${target}_analyze PROPERTIES
                          COMPILE_OPTIONS "${ANALYZER_OPTIONS}"
                          EXCLUDE_FROM_DEFAULT_BUILD true)
endfunction()