PKGBUILD Kitematic

fix_path_tslint.patch

--- package.json	2018-07-03 21:36:27.010262469 -0500
+++ package.json.new	2018-07-03 21:33:00.280257489 -0500
@@ -23,7 +23,7 @@
     "start": "grunt",
     "start-dev": "npm run build && NODE_ENV=development grunt",
     "test": "jest -c jest-unit.json",
-    "tslint": "tslint --fix --project ./tsconfig.json"
+    "tslint": "tslint -c tslint.json -p tsconfig.json --project . -t stylish || echo"
   },
   "electron-version": "1.8.2",
   "dependencies": {

PKGBUILD

# Maintainer: Timur Kiyivinski <timur@linux.com>

pkgname=kitematic-git
pkgver=2231.082bfd5
pkgrel=1
pkgdesc='Visual Docker Container Management'
arch=('x86_64')
url='https://github.com/docker/kitematic'
license=('Apache')
depends=('docker' 'nodejs' 'npm')
makedepends=('git' 'nodejs-grunt-cli')
conflicts=('kitematic')
source=("$pkgname::git+https://github.com/docker/kitematic.git" "${pkgname/\-git/}.desktop" "${pkgname/\-git/}.svg" "fix_path_tslint.patch")
sha256sums=('SKIP'
            '5b1a905c36a22f454a483563bae8036822c35814e8de0d7816a56f3f6355be58'
            '32aafe8f1235a043094e031e9b1b978e26feeb0ebe8232d6269fcb53f1665706'
            '31d80e1b6b310a6c4a893fad5ac10ad9f956e48128902085d08777176696ccc1')

prepare() {
  cd "$pkgname"
  patch -p0 -i "$srcdir"/fix_path_tslint.patch
}

pkgver() {
    cd "$pkgname"
    echo $(git rev-list --count HEAD).$(git rev-parse --short HEAD)
}

build() {
    cd "$pkgname"
    npm install
    grunt babel less copy:dev shell:linux_npm electron-packager:build
}

package() {
    install -dm755 "$pkgdir"/{opt,usr/bin}
    install -Dm644 "${pkgname/\-git/}.svg" "$pkgdir/usr/share/icons/hicolor/scalable/apps/${pkgname/\-git/}.svg"
    install -Dm644 "${pkgname/\-git/}.desktop" "$pkgdir/usr/share/applications/${pkgname/\-git/}.desktop"
    cp -R "$pkgname/dist/Kitematic-linux-x64/" "$pkgdir/opt/$pkgname"
    ln -s "/opt/$pkgname/Kitematic" "$pkgdir/usr/bin/kitematic"
}