Pgmodeler 0.8-alpha Arch Linux

pgmoder

# Maintainer: Roman Titov <titovroman@gmail.com>
pkgname=pgmodeler
pkgver=0.8.0
pkgrel=1
pkgdesc="PostgreSQL Database Modeler: an open source CASE tool for modeling PostgreSQL databases"
url="http://www.pgmodeler.com.br/"
license=('GPL3')
arch=('i686' 'x86_64')
depends=('qt5-base' 'qt5-svg' 'libxml2' 'libsm' 'libpqxx')
makedepends=('qt5-tools')
optdepends=('postgresql')
source=("https://github.com/$pkgname/$pkgname/archive/v$pkgver-alpha.tar.gz"
  'pgmodeler'
  'pgmodeler-cli'
  'pgmodeler_logo.png'
  'pgmodeler_dbm.png'
  'pgmodeler.desktop')
sha1sums=('2574f57d8f25fbfa2209bff26af715f6c8068e9d'
  'f11a0b25b747ab0438d4a3fb47af2caa953e3997'
  '01eab1f1a3c0d163289e9b26855775cc5622acab'
  'c5bb090a1cbb784cd2ec9e1449cac02af2ba6538'
  '4c4e4260f4b2d2d4c154a8fb5cd7060a6585c83a'
  'c1d030bece7af6d7bc12db77de2410ede92eba60')
install='pgmodeler.install'

build() {
  cd "$srcdir/$pkgname-$pkgver-alpha"
  qmake pgmodeler.pro
  make
  make install
}

package() {
  buildir="$srcdir/$pkgname-$pkgver-alpha/build"

  msg2 "Creating required dirs"
  mkdir -p "$pkgdir"/{etc/$pkgname,usr/{bin,share/{applications,icons/hicolor/64x64/{apps,mimetypes},licenses/$pkgname,$pkgname}},opt/$pkgname}

  msg2 "Moving stuff in place"
  cp -R "$buildir"/conf/*.conf "$pkgdir/etc/$pkgname/"
  cp -R "$buildir"/conf/{schemas,defaults,dtd,example.dbm} "$pkgdir/usr/share/$pkgname/"
  cp -R "$buildir"/* "$pkgdir/opt/$pkgname/"

  local fmp=''
  for fmp in schemas dtd;
  do
    ln -s "/usr/share/$pkgname/$fmp" "$pkgdir/etc/$pkgname/$fmp"
  done
  ln -s "/usr/share/$pkgname/example.dbm" "$pkgdir/etc/$pkgname/example.dbm"

  install -m755 "$srcdir/pgmodeler" "$pkgdir/usr/bin"
  install -m755 "$srcdir/pgmodeler-cli" "$pkgdir/usr/bin"
  install -m644 "$srcdir/pgmodeler_logo.png" "$pkgdir/usr/share/icons/hicolor/64x64/apps/pgmodeler.png"
  #install -m644 "$srcdir/pgmodeler_dbm.png" "$pkgdir/usr/share/icons/hicolor/64x64/mimetypes/TODO_REGISTER_MIME_ICON.png"
  install -m644 "$srcdir/pgmodeler.desktop" "$pkgdir/usr/share/applications"

  msg2 "Removing redundant files"
  rm -rf "$pkgdir/opt/$pkgname/"{conf,LICENSE,pgmodeler.vars}
}