day_07.ex

defmodule AdventOfCode.Day07 do
  defp parse(input) do
    input
    |> String.split("\n", trim: true)
    |> Enum.map(fn l ->
      [cards, bid] = String.split(l)
      {String.to_charlist(cards), String.to_integer(bid)}
    end)
  end

  defp occ(hand, part) do
    score =
      hand
      |> Enum.reject(&(part == 2 && &1 == ?J))
      |> Enum.frequencies()
      |> Map.values()
      |> Enum.sort(:desc)
      |> Enum.concat([0, 0])

    [length(hand) - Enum.sum(score) + Enum.at(score, 0), Enum.at(score, 1)]
  end

  @order1 Enum.with_index(~c"23456789TJQKA") |> Map.new()
  @order2 Enum.with_index(~c"J23456789TQKA") |> Map.new()

  defp hand_order(hand, part) do
    order = Enum.at([@order1, @order2], part - 1)

    hand |> Enum.reduce(0, &(&2 * 14 + Map.get(order, &1)))
  end

  defp part(input, part) do
    parse(input)
    |> Enum.sort_by(&hand_order(elem(&1, 0), part))
    |> Enum.sort_by(&occ(elem(&1, 0), part))
    |> Enum.with_index(1)
    |> Enum.map(&(elem(elem(&1, 0), 1) * elem(&1, 1)))
    |> Enum.sum()
  end

  def part1(input) do
    part(input, 1)
  end

  def part2(input) do
    part(input, 2)
  end
end