gistfile1.ino

/*
Liquid flow rate sensor -DIYhacking.com Arvind Sanjeev

Measure the liquid/water flow rate using this code. 
Connect Vcc and Gnd of sensor to arduino, and the 
signal line to arduino digital pin 2.
 
 */

byte statusLed    = 13;

byte sensorInterrupt = 0;  // 0 = digital pin 2
byte sensorPin       = 2;

// The hall-effect flow sensor outputs approximately 4.5 pulses per second per
// litre/minute of flow.
float calibrationFactor = 4.5;

volatile byte pulseCount;  

float flowRate;
unsigned int flowMilliLitres;
unsigned long totalMilliLitres;

unsigned long oldTime;

void setup()
{
  
  // Initialize a serial connection for reporting values to the host
  Serial.begin(38400);
   
  // Set up the status LED line as an output
  pinMode(statusLed, OUTPUT);
  digitalWrite(statusLed, HIGH);  // We have an active-low LED attached
  
  pinMode(sensorPin, INPUT);
  digitalWrite(sensorPin, HIGH);

  pulseCount        = 0;
  flowRate          = 0.0;
  flowMilliLitres   = 0;
  totalMilliLitres  = 0;
  oldTime           = 0;

  // The Hall-effect sensor is connected to pin 2 which uses interrupt 0.
  // Configured to trigger on a FALLING state change (transition from HIGH
  // state to LOW state)
  attachInterrupt(sensorInterrupt, pulseCounter, FALLING);
}

/**
 * Main program loop
 */
void loop()
{
   
   if((millis() - oldTime) > 1000)    // Only process counters once per second
  { 
    // Disable the interrupt while calculating flow rate and sending the value to
    // the host
    detachInterrupt(sensorInterrupt);
        
    // Because this loop may not complete in exactly 1 second intervals we calculate
    // the number of milliseconds that have passed since the last execution and use
    // that to scale the output. We also apply the calibrationFactor to scale the output
    // based on the number of pulses per second per units of measure (litres/minute in
    // this case) coming from the sensor.
    flowRate = ((1000.0 / (millis() - oldTime)) * pulseCount) / calibrationFactor;
    
    // Note the time this processing pass was executed. Note that because we've
    // disabled interrupts the millis() function won't actually be incrementing right
    // at this point, but it will still return the value it was set to just before
    // interrupts went away.
    oldTime = millis();
    
    // Divide the flow rate in litres/minute by 60 to determine how many litres have
    // passed through the sensor in this 1 second interval, then multiply by 1000 to
    // convert to millilitres.
    flowMilliLitres = (flowRate / 60) * 1000;
    
    // Add the millilitres passed in this second to the cumulative total
    totalMilliLitres += flowMilliLitres;
      
    unsigned int frac;
    
    // Print the flow rate for this second in litres / minute
    Serial.print("Flow rate: ");
    Serial.print(int(flowRate));  // Print the integer part of the variable
    Serial.print(".");             // Print the decimal point
    // Determine the fractional part. The 10 multiplier gives us 1 decimal place.
    frac = (flowRate - int(flowRate)) * 10;
    Serial.print(frac, DEC) ;      // Print the fractional part of the variable
    Serial.print("L/min");
    // Print the number of litres flowed in this second
    Serial.print("  Current Liquid Flowing: ");             // Output separator
    Serial.print(flowMilliLitres);
    Serial.print("mL/Sec");

    // Print the cumulative total of litres flowed since starting
    Serial.print("  Output Liquid Quantity: ");             // Output separator
    Serial.print(totalMilliLitres);
    Serial.println("mL"); 

    // Reset the pulse counter so we can start incrementing again
    pulseCount = 0;
    
    // Enable the interrupt again now that we've finished sending output
    attachInterrupt(sensorInterrupt, pulseCounter, FALLING);
  }
}

/*
Insterrupt Service Routine
 */
void pulseCounter()
{
  // Increment the pulse counter
  pulseCount++;
}

1. El loop se ejecuta si han pasado al menos 1001 milisegundo (1 seg) desde la última pasada. Esto se hace porque el sensor reporta datos cada 1 segundo.
   L58:
   if((millis() - oldTime) > 1000)

2. Cuando entra al loop se “cierra” la interrupción de manera que el sensor no reporte más datos durante la ejecución del loop actual.
   L62:
   detachInterrupt(sensorInterrupt);

   Debido a que cuando esto ocurre el arduino detiene el contador de tiempo, --o sea el valor de millis() ya no cambia-- la pequeña cantidad de flujo que no se cuenta durante este instante no importa.

3. El sensor envía 4.5 pulsos por segundo por cada litro por minuto de flujo.
   L17:

   // The hall-effect flow sensor outputs approximately 4.5 pulses per second per
   // litre/minute of flow.
   float calibrationFactor = 4.5;
   

   Esto quiere decir q si el flujo es de 1 lt/minuto en un instante(segundo) dado entonces la variable pulseCount debe tener el valor de 4.5. Esto es en teoría, en realidad el pulseCount sólo aumenta de a 1, o sea su valor siempre es un entero, es decir, 1,2,3,4,5 …

   L119:
   pulseCount++

   Si por ej. durante el último segundo (o el loop actual) el pulseCount tiene un valor de 6.0, eso significa que durante ese “instante” el flujo es de 6.0/4.5 = 1.34 lt/minuto.
   Es decir: pulseCount / calibrationFactor .

4. Como el loop se ejecuta si han transcurrido al menos 1001 milisegundos, entonces debemos ajustar el valor pulseCount / calibrationFactor para que se “sincronice” con el segundo actual. Esto se hace dividiendo este valor por el tiempo que tomó el loop, o sea

   (1000.0 / (millis() - oldTime)) en

   L69:
   flowRate = ((1000.0 / (millis() - oldTime)) * pulseCount) / calibrationFactor;

   Se sabe que este valor siempre es mayor que 1001, o sea que la división anterior dará un número menor que 1, sólo un poquito menor que uno, porque seguro que en cada loop el valor de millis() - oldTime - 1000 es muy pequeño, yo diría q es menor que 10.

5. Al final del loop se “abre” la interrupción de manera que el sensor comience a reportar datos nuevamente.
   L109:
   attachInterrupt(sensorInterrupt, pulseCounter, FALLING);