Unityでアルファブレンドするトランジション用のシェーダ

Transition.shader

Shader "Custom/Transition" {
	Properties {
		_MainTex ("Base (RGB)", 2D) = "white" {}
		_Color ("Base Color", Color) = (0, 0, 0, 1)
		_Cutoff ("Alpha cutoff", Range(0,1)) = 0.0
		_Step ("Step", Range(0, 1)) = 0.0
	}
	
	SubShader {
		Tags {"Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="TransparentCutout"}
		LOD 100

		Lighting Off

		ZWrite Off
		Blend SrcAlpha OneMinusSrcAlpha 

		Pass {  
			CGPROGRAM
				#pragma vertex vert
				#pragma fragment frag
				
				#include "UnityCG.cginc"

				struct appdata_t {
					float4 vertex : POSITION;
					float2 texcoord : TEXCOORD0;
				};

				struct v2f {
					float4 vertex : SV_POSITION;
					half2 texcoord : TEXCOORD0;
				};

				sampler2D _MainTex;
				float4 _MainTex_ST;
				fixed4 _Color;
				fixed _Cutoff;
				fixed _Step;

				v2f vert(appdata_t v)
				{
					v2f o;
					o.vertex = mul(UNITY_MATRIX_MVP, v.vertex);
					o.texcoord = TRANSFORM_TEX(v.texcoord, _MainTex);
					return o;
				}
				
				fixed4 frag(v2f i) : COLOR
				{
					fixed4 col = tex2D(_MainTex, i.texcoord);
					float a = col.a * max(1.0 - _Step, 0.0) + _Step;
					
					if(a < _Cutoff + 1.0 / 256.0) {
						discard;
					}
					
					fixed4 ret = _Color;
					
				    if(a < _Cutoff + _Step) {
				        ret.a = smoothstep(_Cutoff, _Cutoff + _Step, a);
				    }
					
					return ret;
				}
			ENDCG
		}
	}
}