Evernote Mac - Put Classic Note Link on Clipboard -- AppleScript

Copy Classic Link (Evernote).scpt

(*
  SCRIPT NAME:  Copy Classic Link (Evernote)
  
  DATE:  Tue, Feb 07, 2017    VER: 1.0.0
  
  PURPOSE:
    •  Get Classic link of selected Evernote Note
    •  Copy to Mac Clipboard
    •  Link is the "Classic", internal link to EN Mac Note
    
  AUTHOR: Julian J. Schrader
          Please email mail@jjs.de with any bugs/issues/questions
        
  INSTALLATION:
    • Use Mac OS X's Automator to create a new SERVICE
    • Set it to accept “no input” in “Evernote”
    • Add one “Run AppleScript” action
    • Copy and paste this script into the action
    • Save the new service
    • Go to “System Preferences” > “Keyboard” > “Shortcuts” > “Services”, find your new service in the list and set a keyboard shortcut (e. g. ⌘⌥C)
  
  REF:
    • I was inspired by and adapted JMichaelTX's code:
	https://gist.github.com/JMichaelTX/0b14e9755ed77f347816
======================================================================
*)


tell application "Evernote"
	set lstSelectedNotes to selection
	
	if lstSelectedNotes ≠ {} then
		
		--- GET THE FIRST NOTE ---
		set oNote to first item of lstSelectedNotes
		
		--- GET THE NOTE TITLE AND CLASSIC NOTE LINK ---
		set strNoteTitle to title of oNote
		set strNoteLink to note link of oNote
		
		--- COPY TITLE AND LINK TO THE CLIPBOARD ---
		set lstrCMD to "echo " & quoted form of strNoteLink & " | pbcopy -Prefer txt"
		do shell script lstrCMD
		
		set strMsg to strNoteTitle
		set strMTitle to "Evernote Internal Link Copied to Clipboard for"
		display notification strMsg with title strMTitle sound name "Hero.aiff"
		
	end if -- lstSelectedNotes ≠ {}
	
end tell

Thanks for putting this together. Huge life saver. Been looking for this for quite some time so it was nice to see this. Instructions for setting up were spot on and pretty easy to do. Thanks again!

Hi, thanks for helping me find a way to get the classic link!
Can you tell me how I'd modify this so that instead of the quoted form, I can paste the form that includes the note title, please?

@joshuawagner I guess you want to modify line 42 to something like this:

set lstrCMD to "echo " & quoted form of strNoteTitle & " " & quoted form of strNoteLink & " | pbcopy -Prefer txt"

You'll need to experiment to find the format you want – you basically want to add strNoteTitle to the string that's copied to your clipboard.