Minimal FRP example

Main.hs

import FRP.Sodium
import FRP.Sodium.IO

import System.Exit (exitSuccess)
import Control.Applicative ((<$>))
import Control.Monad (forever)
import Control.Concurrent
import Control.Monad

import System.Timeout

main :: IO()
main = do
    -- Create a new event and a function to push
    -- values into it of type (a -> Reactive a)
    (clock,pushClock) <- sync newEvent
    (inputEvent,pushInput) <- sync newEvent

    counter <- sync $ buildCounter inputEvent
    clockThread 2 pushClock

    sync $ listen (printCounter counter clock) (id)

    gatherStdIn pushInput

buildCounter :: Event Char -> Reactive (Behaviour Int)
buildCounter charEvent =
  accum 0 increases
  where
    increases = (const $ (+1)) <$> charEvent

printCounter :: Behaviour Int -> Event () -> Event (IO ())
printCounter counter clockEvent = counterPrintE `merge` clockPrintE
  where
    counterChangeE = updates counter
    counterPrintE = (\c -> putStrLn $ "\n" ++ (show c)) <$> counterChangeE
    clockPrintE = snapshot clockPrintF clockEvent counter
    clockPrintF () i = putStrLn $ "\nTimer event: "  ++ (show i)

clockThread :: Int -> (() -> Reactive ()) -> IO ThreadId
clockThread sleepS pushE = forkIO $ forever $ do
  threadDelay sleepTime
  sync $ pushE ()
  where
    -- Sleep time is in microseconds, but input is in seconds
    sleepTime = sleepS * 1000 * 1000

gatherStdIn :: (Char -> Reactive ()) -> IO ()
gatherStdIn pushChar = forever $
  getChar >>= (sync . pushChar)