item_roller_device.verse

using { /Fortnite.com/Devices }
using { /Verse.org/Simulation }
using { /UnrealEngine.com/Temporary/Diagnostics }

item_roller_device := class(creative_device):

    @editable RollTime:float = 5.0
    @editable PickupTimeout:float = 5.0
    @editable RollCycleDelay:float = 0.1
    
    @editable TriggerRoll:trigger_device = trigger_device{}
    @editable ItemSpawner:item_spawner_device = item_spawner_device{}

    # Runs when the device is started in a running game
    OnBegin<override>()<suspends>:void=
        TriggerRoll.TriggeredEvent.Subscribe(StartRoll)
        
    StartRoll(MaybeAgent: ?agent):void =    
        if:
            Agent := MaybeAgent?
        then:
            spawn:
                Roll(Agent)

    Roll(Agent: agent)<suspends>: void =
        ItemSpawner.Enable()
        Print("Enabled Item Spawner")
        
        # Do Roll
        race:
            block:
                Sleep(RollTime) # yields
            loop:
                Sleep(RollCycleDelay) # yields
                ItemSpawner.CycleToNextItem()
        Print("Box roll stopped.  Awaiting next action... ")
        
        # Wait for Pickup
        race:
            block:
                ItemSpawner.ItemPickedUpEvent.Await() # yields
                Print("Item Picked Up")
            block:
                Sleep(PickupTimeout) # yields
                ItemSpawner.Disable()
                Print("Disabled Item Spawner")

    Roll2(Agent: agent)<suspends>: void =
        ItemSpawner.Enable()
        Print("Enabled Item Spawner")
        
        race:
            block:
                # Watch for Pickup
                ItemSpawner.ItemPickedUpEvent.Await() # yields
                Print("Item Picked Up")
            block:
                # Do Roll
                race:
                    block:
                        Sleep(RollTime) # yields
                    loop:
                        Sleep(RollCycleDelay) # yields
                        ItemSpawner.CycleToNextItem()
                Print("Box roll stopped.  Awaiting next action... ")
                Sleep(PickupTimeout) # yields
                ItemSpawner.Disable()
                Print("Disabled Item Spawner")