Safari - Build Text Link List from Tabs

Build text link list from Tabs.applescript

global linkText

on run
	set linkText to ""
	
	tell application "Safari"
		activate
		set w to window 1
		
		set n to 0
		try -- this will fail for the downloads window
			set n to count tabs of w
		end try
		
		if n > 1 then
			repeat with t in every tab of w
				my appendLineWithDoc(t)
			end repeat
		else if n = 1 then
			my appendLineWithDoc(document of w)
		end if
	end tell
	
	set the clipboard to linkText
	
	return linkText
end run

on appendLineWithDoc(theDoc)
	tell application "Safari"
		tell theDoc
			try
				set linkText to linkText & name
				set linkText to linkText & return & "<" & URL & ">" & return & return
			end try
		end tell
	end tell
end appendLineWithDoc

A bit more compact:

property text item delimiters : linefeed
set links to {}

tell application id "com.apple.Safari" to tell ¬
	tabs in windows to repeat with T in it
	tell T to set the end of my links to ¬
		{name, "<" & URL & ">", ""}
end repeat

set the clipboard to the links as text
get the clipboard

Or, for markdown links:

property text item delimiters : linefeed
set links to {}

tell application id "com.apple.Safari" to tell ¬
	tabs in windows to repeat with T in it
	tell T to set the end of my links to [¬
		"[", name, "]", ¬
		"(", URL, ")"]
end repeat

set the clipboard to the links as text
get the clipboard