Last active
August 15, 2023 15:57
-
-
Save seanmiddleditch/c70a4e46ed1b52145c097e4a632172a8 to your computer and use it in GitHub Desktop.
Modernized FindSDL2 module for CMake with improved Windows support
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
# This module defines the library modules | |
# SDL2::SDL2 and SDL2::SDL2main | |
# | |
# Don't forget to include SDLmain.h and SDLmain.m your project for the | |
# OS X framework based version. (Other versions link to -lSDL2main which | |
# this module will try to find on your behalf.) Also for OS X, this | |
# module will automatically add the -framework Cocoa on your behalf. | |
# | |
# | |
# Additional Note: If you see an empty SDL2_LIBRARY_TEMP in your configuration | |
# and no SDL2_LIBRARY, it means CMake did not find your SDL2 library | |
# (SDL2.dll, libsdl2.so, SDL2.framework, etc). | |
# Set SDL2_LIBRARY_TEMP to point to your SDL2 library, and configure again. | |
# Similarly, if you see an empty SDL2MAIN_LIBRARY, you should set this value | |
# as appropriate. These values are used to generate the final SDL2_LIBRARY | |
# variable, but when these values are unset, SDL2_LIBRARY does not get created. | |
# | |
# | |
# $SDL2DIR is an environment variable that would | |
# correspond to the ./configure --prefix=$SDL2DIR | |
# used in building SDL2. | |
# l.e.galup 9-20-02 | |
# | |
# Modified by Eric Wing. | |
# Added code to assist with automated building by using environmental variables | |
# and providing a more controlled/consistent search behavior. | |
# Added new modifications to recognize OS X frameworks and | |
# additional Unix paths (FreeBSD, etc). | |
# Also corrected the header search path to follow "proper" SDL guidelines. | |
# Added a search for SDL2main which is needed by some platforms. | |
# Added a search for threads which is needed by some platforms. | |
# Added needed compile switches for MinGW. | |
# | |
# On OSX, this will prefer the Framework version (if found) over others. | |
# People will have to manually change the cache values of | |
# SDL2_LIBRARY to override this selection or set the CMake environment | |
# CMAKE_INCLUDE_PATH to modify the search paths. | |
# | |
# Note that the header path has changed from SDL2/SDL.h to just SDL.h | |
# This needed to change because "proper" SDL convention | |
# is #include "SDL.h", not <SDL2/SDL.h>. This is done for portability | |
# reasons because not all systems place things in SDL2/ (see FreeBSD). | |
# | |
# Modified by Sean Middleditch | |
# Added automatic creation of SDL2::SDL2 and SDL2::SDL2main libraries. | |
# Added correct usage of Windows DLL. | |
#============================================================================= | |
# Copyright 2003-2009 Kitware, Inc. | |
# | |
# Distributed under the OSI-approved BSD License (the "License"); | |
# see accompanying file Copyright.txt for details. | |
# | |
# This software is distributed WITHOUT ANY WARRANTY; without even the | |
# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. | |
# See the License for more information. | |
#============================================================================= | |
# (To distribute this file outside of CMake, substitute the full | |
# License text for the above reference.) | |
# message("<FindSDL2.cmake>") | |
set(SDL2_SEARCH_PATHS | |
~/Library/Frameworks | |
/Library/Frameworks | |
/usr/local | |
/usr | |
/sw # Fink | |
/opt/local # DarwinPorts | |
/opt/csw # Blastwave | |
/opt | |
${SDL2_PATH} | |
) | |
find_path(SDL2_INCLUDE_DIR SDL.h | |
HINTS $ENV{SDL2DIR} | |
PATH_SUFFIXES include/SDL2 include | |
PATHS ${SDL2_SEARCH_PATHS} | |
) | |
if(CMAKE_SIZEOF_VOID_P EQUAL 8) | |
set(PATH_SUFFIXES lib64 lib/x64 lib) | |
else() | |
set(PATH_SUFFIXES lib/x86 lib) | |
endif() | |
find_library(SDL2_LIBRARY_TEMP | |
NAMES SDL2 | |
HINTS $ENV{SDL2DIR} | |
PATH_SUFFIXES ${PATH_SUFFIXES} | |
PATHS ${SDL2_SEARCH_PATHS} | |
) | |
if(NOT ${SDL2_INCLUDE_DIR} MATCHES ".framework") | |
# Non-OS X framework versions expect you to also dynamically link to | |
# SDL2main. This is mainly for Windows and OS X. Other (Unix) platforms | |
# seem to provide SDL2main for compatibility even though they don't | |
# necessarily need it. | |
find_library(SDL2MAIN_LIBRARY | |
NAMES SDL2main | |
HINTS $ENV{SDL2DIR} | |
PATH_SUFFIXES ${PATH_SUFFIXES} | |
PATHS ${SDL2_SEARCH_PATHS} | |
) | |
endif(NOT ${SDL2_INCLUDE_DIR} MATCHES ".framework") | |
if(SDL2_LIBRARY_TEMP) | |
set(SDL2_INTERFACE_LIBRARIES "" CACHE INTERNAL "") | |
# For OS X, SDL2 uses Cocoa as a backend so it must link to Cocoa. | |
# CMake doesn't display the -framework Cocoa string in the UI even | |
# though it actually is there if I modify a pre-used variable. | |
# I think it has something to do with the CACHE STRING. | |
# So I use a temporary variable until the end so I can set the | |
# "real" variable in one-shot. | |
if(APPLE) | |
list(APPEND SDL2_INTERFACE_LIBRARIES "-framework Cocoa") | |
endif(APPLE) | |
# SDL2 may require threads on your system. | |
# The Apple build may not need an explicit flag because one of the | |
# frameworks may already provide it. | |
# But for non-OSX systems, I will use the CMake Threads package. | |
if(NOT APPLE) | |
find_package(Threads) | |
list(APPEND SDL2_INTERFACE_LIBRARIES ${CMAKE_THREAD_LIBS_INIT}) | |
endif(NOT APPLE) | |
# MinGW needs an additional link flag, -mwindows | |
# It's total link flags should look like -lmingw32 -lSDL2main -lSDL2 -mwindows | |
if(MINGW) | |
set(MINGW32_LIBRARY mingw32 "-mwindows" CACHE STRING "mwindows for MinGW") | |
list(APPEND SDL2_INTERFACE_LIBRARIES ${MINGW32_LIBRARY}) | |
endif(MINGW) | |
# Set the final string here so the GUI reflects the final state. | |
set(SDL2_LIBRARY ${SDL2_LIBRARY_TEMP} CACHE STRING "Where the SDL2 Library can be found") | |
# Set the temp variable to INTERNAL so it is not seen in the CMake GUI | |
set(SDL2_LIBRARY_TEMP "${SDL2_LIBRARY_TEMP}" CACHE INTERNAL "") | |
add_library(SDL2 IMPORTED SHARED GLOBAL) | |
add_library(SDL2::SDL2 ALIAS SDL2) | |
set_target_properties(SDL2 PROPERTIES | |
INTERFACE_INCLUDE_DIRECTORIES ${SDL2_INCLUDE_DIR} | |
IMPORTED_LINK_INTERFACE_LIBRARIES "${SDL2_INTERFACE_LIBRARIES}" | |
) | |
add_library(SDL2main IMPORTED STATIC GLOBAL) | |
add_library(SDL2::SDL2main ALIAS SDL2main) | |
set_target_properties(SDL2main PROPERTIES IMPORTED_LOCATION ${SDL2MAIN_LIBRARY}) | |
if(WIN32) | |
string(REPLACE ".lib" ".dll" SDL2_LIBRARY_DLL ${SDL2_LIBRARY}) | |
set_target_properties(SDL2 PROPERTIES IMPORTED_LOCATION ${SDL2_LIBRARY_DLL} IMPORTED_IMPLIB ${SDL2_LIBRARY}) | |
else(WIN32) | |
set_target_properties(SDL2 PROPERTIES IMPORTED_LOCATION ${SDL2_LIBRARY}) | |
endif(WIN32) | |
endif(SDL2_LIBRARY_TEMP) | |
# message("</FindSDL2.cmake>") | |
INCLUDE(FindPackageHandleStandardArgs) | |
FIND_PACKAGE_HANDLE_STANDARD_ARGS(SDL2 REQUIRED_VARS SDL2_LIBRARY SDL2_INCLUDE_DIR) |
Sign up for free
to join this conversation on GitHub.
Already have an account?
Sign in to comment
On Windows you might also want to copy the SDL2.dll into the output directory of your executable binary. Use a snippet like: