selfie dungeon inform

selfie-dungeon.ni

"dungeon-planet" by Joseph Parker



Chapter 1 - Rules



Section 1(a) - Substance

A material is a kind of value. 

The materials are stone, crystal, glass, wood, paper, bronze, copper, tin, silver, lead, iron, steel, dirt, sand, clay, flesh, bone, leather, cotton, sustenance and air. 

A thing has a material. Things are usually stone. People are usually flesh. 

Substance relates a thing (called the item) to a material (called the stuff) when the material of the item is the stuff. 

The verb to be made of implies the substance relation.

Definition: 
	A thing is metallic if it is made of bronze or it is made of copper or it is made of tin or it is made of silver or it is made of iron or it is made of steel.

A thing can be constructed or elemental. Things are usually elemental.

Understand the material property as describing a thing when the item described is constructed.

Before printing the name of a constructed thing(called W), say "[the material of W] ".



Section 1(b) - Dice

[via http://inform7.com/learn/eg/rota/source.html]

A die roll is a kind of value. 3d20+9 specifies a die roll with parts dice, sides (without leading zeros), adds (without leading zeros, optional, preamble optional).

To decide which number is roll of (dr - a die roll):
	let the total be the adds part of dr;
	repeat with counter running from 1 to the dice part of dr:
		let the roll be a random number from 1 to the sides part of dr;
		increase the total by the roll;
	if the adds part of dr is 0 and the dice part of dr is 1, decide on the total;
	decide on the total.

Test rolling is an action out of world applying to one die roll. Understand "dice [die roll]" as test rolling. Carry out test rolling: say "For your own amusement, you roll "; let the total thrown be the roll of the die roll understood; say ", making [total thrown in words]."




Section 2(a) - Inventory

Instead of taking inventory:
	Let EQ be the list of things worn by the actor;
	Say "Equipment: [line break]";
	Repeat with I running through EQ:
		Say "    [I]";
		If I is a container(called H):
			Say ":[line break]";
			Let HS be the list of things contained by H;
			Repeat with II running through HS:
				Say "        [II][line break]";
		Else: 
			Say "[line break]";
	Let INV be the list of unworn things held by the actor;
	Say "Inventory: [line break]";
	Repeat with I running through INV:
		Say "    [I][line break]".



Section 2(b) - Equipment

A weapon is a kind of thing. 

Weapons have a die roll called damage. The damage of a weapon is usually 1d5. 

Weapons are constructed. Weapons are usually bronze.

After printing the name of a weapon(called W):
	Say " ([damage of W])".
	


Section 2(c) - Photography

A camera is a kind of container.
An iphone is a kind of camera.
A photograph is a kind of thing.
A fancy gradient is a thing.
The archetypal iphone is an iphone.
The jpg is a photograph.

The description of an iphone is "It's screen is a grid of apps. The background image is [a fancy gradient]"

A cat is a kind of thing

Subjection relates one photograph to various things.

The verb to capture implies the subjection relation.

The description of a photograph is "It is a picture of [list of things captured by photograph with indefinite articles].".

After printing the name of a photograph:
	Say " of [list of things captured by photograph with indefinite articles]"

Photographing it with is an action applying to two visible thing. 

Understand "take a photo of [something] with [camera]" as photographing it with.

After an actor photographing something (called the subject)  with something (called the device):
	say "[The actor] hold up [the device] and takes a photo of [the noun]";
	say "[line break]Click!";
	Now the jpg is in the device;
	Now the jpg captures the subject;
	[Let photobomb be a random thing in the location of the subject;
	Now the jpg captures the photobomb.]




Section 3(a) - Mortality

A person can be alive or dead. People are usually alive.

Instead of someone dead doing something:
	Rule fails.




Before printing the name of a dead person (called the stiff):
	Say "[one of]dead [or]slain [or][sticky random]".

After printing the name of a dead person (called the stiff):
	say "'s[one of] body[or] corpse[or] remains[sticky random]".


Every person has a number called hp. 

The hp of a person is usually 12.

Every person has a number called maxhp.

When play begins:
	Repeat with patient running through the list of alive people:
		Now the maxhp of the patient is the hp of the patient.

Every turn:
	Now the command prompt is "[hp of player]/[maxhp of player]>".

To hurt (victim - a person) for (amount - a number):
	Decrease the hp of the victim by the amount;
	If the hp of the victim < 1:
		Say "[The victim] dies!";
		Repeat with item running through the list of things held by the victim:
			Move the item to the location of the victim;
		Now the victim is dead;
		If the victim is the player:
			End the story saying "you have died.".
	


Section 3(b) - Attacking

To decide what die roll is the attack die of (attacker - a thing):
	If the attacker has a weapon:
		decide on the damage of a random weapon held by the attacker;
	decide on 1d2.

The block attacking rule is not listed in any rulebook.


Report an actor attacking someone:
	let attempt be the roll of 3d4;
	If attempt > 7:
		let result be the roll of the attack die of the actor;
		Say "[The actor] [one of]strike[s][or]hit[s][or]land[s] a blow on[at random] ";
		Say "[if noun is the player]you[else][the noun][end if] ";
		Say "for [result]!";
		Hurt the noun for result;
	Else:
		Say "[The actor] misses [if noun is the player]you.[else][the noun].".


Chapter 2 - Objects

Section 1 - weapons

[Some kinds of weapon are defined by the table of weaponry.]

[Table of Weaponry
name	damage		
dagger	1d3			
hammer	2d3			
hatchet	1d5]	

A sword is a kind of weapon. "A thin [material of noun] sword with a simple hilt.  It's scratched and beginning to corrode."
The damage of the sword is 1d6.

knife is a kind of weapon. The damage of the knife is 1d2.

A hammer is a kind of weapon. The damage of a hammer is 2d3.
		



Section 2 - containers

Containers are constructed. Containers are usually wood.

Definition: A container is transparent if it is made of glass or it is made of crystal.



Section 4 - clothing

Definition: A thing is unworn if it is not worn.

Clothing is a kind of thing.  Clothing is wearable. Clothing is usually constructed. Clothing is usually cotton.

Player's holdalls are constructed. A player's holdall is usually cotton.

Backpacks are a kind of player's holdall.
Shirts are a kind of clothing. 
Trousers are a kind of clothing. 
Gloves are a kind of clothing. 
Hats are a kind of clothing.



Chapter 3 - Monsters

A monster is a kind of person.

After examining a monster (called M):
	If M has a weapon (called W):
		Say "[M] is wielding [W]".

Every turn:
	If a monster (called M) is inside an open container (called C):
		Try M exiting;
	If a monster can see someone holding two weapons:
		Try M exiting;
	If a monster (called M) can see the player:
		Try M attacking the player.
		

A skeleton is a kind of monster. 
Skeletons are usually bone.
Every skeleton carries a stone knife.

Understand "give [something](to|) [someone]" as giving it to (with nouns reversed).

Instead of giving something(called T) to a skeleton(called SK):
	Say "The [SK] grabs the [T] from your hands and gobbles it up!";
	Now the SK has the T;
	rule succeeds.





Chapter 4 - Rooms

The Damp Crypt is a room. "Cobwebs hang from the corners of a small damp room.  A number of stone burial vessels are arranged haphazardly along it's perimeter. Behind you to the west is the dark hallway you entered from."

The Dark Hallway is a room. "You tread lightly on the dirt floor of this stone hallway. A dim glow is coming from a chamber to the east."  The Dark Hallway is west of the Damp Crypt.


The player is wearing a cotton shirt, a leather trousers, and a leather hat.
The backpack is a player's holdall. The backpack is leather. The player is wearing the backpack.

The player is holding a lead hammer called mallet. The damage of mallet is 3d3+1.

The player is holding an iphone.

The player is in the dark hallway.

A sign on the wall is here. "A wooden sign bolted to the wall. It reads 'Woe Ye Wither Come Here.'"

A monster called the goblin is here. The goblin carries a brass knife.

A dead frog is here. A dead skeleton called the skeleton is here.

A coffin is a closed, openable container in the Damp Crypt.  It is wood. 
Inside the coffin is a sword, a skeleton, and a silver coin.

A chest is a closed, openable container in the Damp Crypt. It is glass.
Inside the chest is an iron knife.