Fix for Robolectric and Bitrise issue

.gitignore

# ignore Robolectric jar dependencies

#Robolectric jars for unit tests
/robolectric/*.jar

build.gradle

// add this line into your root build.gradle
//  and make sure to run `fetchRobolectricDependencies` gradle task before running your tests
//  e.g. `./gradlew fetchRobolectricDependencies test`

apply from: "$rootDir/robolectric.gradle"

robolectric.gradle

// add this file into your root directory

configurations {
  robo32Instrumented
  robo33Instrumented
}

dependencies {
  robo32Instrumented "org.robolectric:android-all-instrumented:12.1-robolectric-8229987-i4"
  robo33Instrumented "org.robolectric:android-all-instrumented:13-robolectric-9030017-i4"
}

def robolectricDependencies = "$rootDir/robolectric"

tasks.register('fetchRobolectricDependencies', Copy) {
  from configurations.robo32Instrumented
  from configurations.robo33Instrumented
  into robolectricDependencies
}

subprojects {
  afterEvaluate {
    if (project.plugins.hasPlugin("com.android.application") || project.plugins.hasPlugin("com.android.library")) {
      android {
        testOptions.unitTests.all {
          systemProperty 'robolectric.offline', 'true'
          systemProperty 'robolectric.dependency.dir', robolectricDependencies
        }
      }
    }
  }
}