Clojure Mutable Stack using clojure.lang.Volatile

00_volatile_stack.clj

(def ^:dynamic *eval-mode* :stack)

(defprotocol IVolatileStack
  (vpeek [stack] "Return stack's top item.")
  (vpop! [stack] "Pop top item off the stack, returning the item and mutating the underlying stack.")
  (vpush! [stack item] "Push item onto top of stack. Return mutated stack."))

(extend-type clojure.lang.Volatile
  IVolatileStack
  (vpeek [vol] (peek @vol))

  (vpop! [vol]
    (let [ret (vpeek vol)]
      (vswap! vol pop)
      ret))

  (vpush! [vol item]
    (vswap! vol conj item)))

01_eval_with_stack.clj

(defn eval-stack
  [forms]
  (let [stack (volatile! [])]
    (letfn [(eval-form [form]
              (if (= form ::with)
                (let [b (vpop! stack)
                      a (vpop! stack)]
                  (vpush! stack (deep-merge a b)))
                (vpush! stack form)))]
      (loop [forms forms]
        (if-let [form (first forms)]
          (do
            (eval-form form)
            (recur (next forms)))
          (vpeek stack))))))

(defn eval*
  [forms]
  (case *eval-mode*
    :stack (eval-stack forms)
    (eval-stack forms)))