Build srcipts for gstreamer on archlinuxarm

gst-plugins-bad

pkgname=gst-plugins-bad
pkgver=1.6.1
pkgrel=1
pkgdesc="GStreamer Multimedia Framework Bad Plugins"
arch=('armv7h')
license=('LGPL')
url="http://gstreamer.freedesktop.org/"
depends=('mjpegtools' 'gst-plugins-base-libs' 'curl' 'libmms' 'faad2' 'mpg123' 'faac' 'celt' 'libdca' 'soundtouch' 'spandsp' 'libdvdnav' 'libmodplug' 'libgme' 'opus' 'wayland' 'neon' 'libofa' 'fluidsynth' 'openjpeg' 'libwebp' 'libsrtp' 'gnutls' 'wildmidi' 'sbc' 'rtmpdump' 'libgudev')
makedepends=('schroedinger' 'libexif' 'libdvdread' 'libmpeg2' 'python' 'wildmidi' 'gobject-introspection' 'ladspa' 'openal' 'libusb')
options=(!emptydirs)
source=(${url}/src/$pkgname/$pkgname-$pkgver.tar.xz
        configure.ac.patch)
sha256sums=('e176a9af125f6874b3d6724aa7566a198fa225d3ece0a7ac2f2b51c57e525466'
            'SKIP')

prepare() {
  cd $pkgname-$pkgver
  #delete camerabin elements from tests
  sed --in-place '252d;281d' ./tests/check/Makefile.am
  #GLESv2 depends on EGL and EGL depends on GLESv2
  patch configure.ac ../configure.ac.patch

  autoreconf -vi
}

build() {
  cd $pkgname-$pkgver

  export LDFLAGS+=" -L/opt/vc/lib"
  export CFLAGS+=" -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux"
  export CPPFLAGS+=" -O2 -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux"
  export LD_LIBRARY_PATH=/opt/vc/lib

  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
    --disable-static --disable-gtk-doc \
    --with-package-name="GStreamer Bad Plugins (Arch Linux)" \
    --with-package-origin="http://www.archlinux.org/" \
    --disable-glx --disable-x11 --disable-wayland --disable-opengl \
    --disable-opencv \
    --disable-orc \
    --disable-accurip \
    --disable-adpcmdec \
    --disable-adpcmenc \
    --disable-audiofxbad \
    --disable-audiovisualizers \
    --disable-camerabin2 \
    --disable-cdxaparse \
    --disable-coloreffects \
    --disable-dccp \
    --disable-dvbsuboverlay \
    --disable-dvdspu \
    --disable-faceoverlay \
    --disable-festival \
    --disable-fieldanalysis \
    --disable-freeverb \
    --disable-frei0r \
    --disable-gaudieffects \
    --disable-geometrictransform \
    --disable-ivtc \
    --disable-jp2kdecimator \
    --disable-librfb \
    --disable-midi \
    --disable-mve \
    --disable-mxf \
    --disable-nuvdemux \
    --disable-patchdetect \
    --disable-pnm \
    --disable-siren \
    --disable-smooth \
    --disable-tta \
    --disable-vmnc \
    --disable-y4m \
    --disable-yadif \
    --disable-directsound \
    --disable-wasapi \
    --disable-direct3d \
    --disable-winscreencap \
    --disable-winks \
    --disable-android_media \
    --disable-apple_media \
    --disable-bluez \
    --disable-shm \
    --disable-vcd \
    --disable-opensles \
    --disable-assrender \
    --disable-voamrwbenc \
    --disable-voaacenc \
    --disable-apexsink \
    --disable-bs2b \
    --disable-bz2 \
    --disable-chromaprint \
    --disable-curl \
    --disable-dash \
    --disable-dc1394 \
    --disable-decklink \
    --disable-directfb \
    --disable-webp \
    --disable-daala \
    --disable-dts \
    --disable-resindvd \
    --disable-faac \
    --disable-faad \
    --disable-fbdev \
    --disable-flite \
    --disable-gsm \
    --disable-fluidsynth \
    --disable-kate \
    --disable-lv2 \
    --disable-libmms \
    --disable-dtls \
    --disable-linsys \
    --disable-mimic \
    --disable-mplex \
    --disable-musepack \
    --disable-nas \
    --disable-neon \
    --disable-ofa \
    --disable-openal \
    --disable-opencv \
    --disable-openexr \
    --disable-openni2 \
    --disable-opus \
    --disable-pvr \
    --disable-rsvg \
    --disable-gtk3 \
    --disable-qt \
    --disable-libvisual \
    --disable-timidity \
    --disable-teletextdec \
    --disable-wildmidi \
    --disable-sdl \
    --disable-smoothstreaming \
    --disable-sndfile \
    --disable-soundtouch \
    --disable-spc \
    --disable-gme \
    --disable-dvb \
    --disable-wininet \
    --disable-acm \
    --disable-vdpau \
    --disable-sbc \
    --disable-schro \
    --disable-zbar \
    --disable-spandsp \
    --disable-gsettings \
    --disable-sndio \
    --disable-hls \
    --disable-x265 \
    --disable-rtmp \
    --enable-experimental \
    --enable-introspection \
    --enable-egl --enable-dispmanx --enable-gles2

  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  make
}

check() {
  cd $pkgname-$pkgver
  export LD_LIBRARY_PATH=/opt/vc/lib
  export GST_GL_WINDOW="dispmanx"
  export GST_GL_PLATFORM="egl"
  export GST_GL_API="gles2"
  export GST_DEBUG=4
  #FIXME: gl* tests fail because "Can't open display"
  make -k check || :
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="${pkgdir}" install
}

gst-plugins-bad configure.ac.patch

--- configure.ac.orig	2015-11-18 13:46:46.321160385 +0000
+++ configure.ac	2015-11-18 13:50:21.159808959 +0000
@@ -720,7 +720,7 @@
             LIBS="$LIBS -lGLESv2"
             AC_CHECK_LIB([EGL], [eglGetProcAddress],
               [
-                LIBS="$LIBS -lEGL"
+                LIBS="$LIBS -lEGL -lGLESv2"
                 AC_CHECK_HEADER([EGL/egl.h],
                   [
                     AC_CHECK_LIB([GLESv2], [glEnable],
@@ -730,7 +730,7 @@
                             HAVE_EGL=yes
                             HAVE_GLES2=yes
                             HAVE_EGL_RPI=yes
-                            EGL_LIBS="-lbcm_host -lvcos -lvchiq_arm"
+                            EGL_LIBS="-lGLESv2 -lbcm_host -lvcos -lvchiq_arm"
                             EGL_CFLAGS=""
                             AC_DEFINE(USE_EGL_RPI, [1], [Use RPi platform])
                           ])

gst-plugins-base

pkgbase=gst-plugins-base
pkgname=('gst-plugins-base-libs' 'gst-plugins-base')
pkgver=1.6.1
pkgrel=1
pkgdesc="GStreamer Multimedia Framework Base Plugins"
arch=('armv7h')
license=('LGPL')
makedepends=('pkgconfig' 'gstreamer' 'alsa-lib' 'libvorbis' 'libtheora' 'gobject-introspection' 'python2' 'freetype2')
options=(!emptydirs)
url="http://gstreamer.freedesktop.org/"
source=(${url}/src/$pkgbase/$pkgbase-${pkgver}.tar.xz)
sha256sums=('9533dcfaa4ee32d435483d9fa88c06b1eba6e9bb234aacd7583f207199f44ba3')

build() {
  cd $pkgbase-$pkgver
  export CPPFLAGS+=" -O2"
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
    --with-package-name="GStreamer Base Plugins (Arch Linux)" \
    --with-package-origin="http://www.archlinux.org/" \
    --disable-gtk-doc \
    --disable-static --enable-experimental \
    --enable-introspection \
    --disable-pango \
    --disable-libvisual \
    --disable-cdparanoia \
    --disable-xshm \
    --disable-xvideo \
    --disable-x \
    --disable-orc


  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  make

  sed -e 's/^SUBDIRS_EXT =.*/SUBDIRS_EXT =/' -i Makefile
}

check() {
  cd $pkgbase-$pkgver
  # Testsuite fails on one test. Some refcount leak
  make check
}

package_gst-plugins-base-libs() {
  pkgdesc="GStreamer Multimedia Framework Base Plugin libraries"
  depends=('gstreamer')

  cd $pkgbase-$pkgver
  make DESTDIR="${pkgdir}" install
}

package_gst-plugins-base() {
  depends=("gst-plugins-base-libs=$pkgver" 'alsa-lib' 'libvorbis' 'libtheora' 'freetype2')

  cd $pkgbase-$pkgver
  make -C gst-libs DESTDIR="${pkgdir}" install
  make -C ext DESTDIR="${pkgdir}" install
  make -C gst-libs DESTDIR="${pkgdir}" uninstall
}

gst-plugins-good

pkgname=gst-plugins-good
pkgver=1.6.1
pkgrel=2
pkgdesc="GStreamer Multimedia Framework Good Plugins"
arch=('armv7h')
license=('LGPL')
url="http://gstreamer.freedesktop.org/"
depends=('libpulse' 'jack2-dbus' 'gst-plugins-base-libs' 'wavpack' 'aalib' 'taglib' 'libdv' 'libshout' 'libvpx' 'gdk-pixbuf2' 'libcaca' 'libavc1394' 'libiec61883' 'libxdamage' 'v4l-utils' 'libgudev')
makedepends=('gstreamer' 'speex' 'flac' 'libraw1394' 'python')
options=(!emptydirs)
source=(${url}/src/$pkgname/$pkgname-$pkgver.tar.xz)
sha256sums=('86d4b814099f7b7b16be19d4b94fa41002ac01fdf1525b07c5764d54c0605935')

build() {
  cd $pkgname-$pkgver

  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
    --disable-static --enable-experimental --disable-gtk-doc \
    --with-package-name="GStreamer Good Plugins (Arch Linux)" \
    --with-package-origin="http://www.archlinux.org/" \
    --disable-orc \
    --disable-soup \
    --disable-alpha \
    --enable-jack \
    --disable-cairo
  # soup and alpha - tests failed
  # cairo - have dependency on mesa


  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  make
}

# Disabled for now: souphttpsrc times out, and takes a damn long time to do so
check() {
  cd $pkgname-$pkgver
  make check
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="${pkgdir}" install
}

gstreamer

pkgname=gstreamer
pkgver=1.6.1
pkgrel=1
pkgdesc="GStreamer Multimedia Framework"
arch=('armv7h')
license=('LGPL')
url="http://gstreamer.freedesktop.org/"
depends=('libxml2' 'glib2')
optdepends=('sh: feedback script')
makedepends=('intltool' 'pkgconfig' 'gtk-doc' 'gobject-introspection' 'python2')
source=(${url}/src/gstreamer/gstreamer-${pkgver}.tar.xz)
sha256sums=('973a3f213c8d41d6dd0e4e7e38fd6cccacd5ae1ac09e1179a8d5d869ef0a5c9c')

build() {
  cd "${srcdir}/gstreamer-${pkgver}"
  export CPPFLAGS+=" -O2"
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libexecdir=/usr/lib \
    --with-package-name="GStreamer (Arch Linux)" \
    --with-package-origin="http://www.archlinux.org/" \
    --disable-gtk-doc \
    --disable-static \
    --enable-introspection \
    --enable-failing-tests

  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  make
}

check() {
  cd "${srcdir}/gstreamer-${pkgver}"
  make check
}

package() {
  cd "${srcdir}/gstreamer-${pkgver}"
  make DESTDIR="${pkgdir}" install
}