Parallel restore script for mysqldump

load.pl

#!/usr/bin/env perl

use strict;
use warnings;

use File::Temp qw/tempfile/;

my ($state, $nprocs) = (0, 0);
my ($fh, $tempfile, @settings);

open(my $pipe, '|-', qw/mysql -u root tpcc/) or die $!;

while (my $line = <STDIN>) {
    if ($line =~ /^-- Table structure/) {
        ($fh, $tempfile) = tempfile();
        $state = 1;
    }

    if ($state == 0) {
        push @settings, $line;
        print $pipe $line;
    } elsif ($state == 1) {
        print $fh $line;
    }

    if ($line =~ /^UNLOCK TABLES;/) {
        close($fh);
        $state = 0;

        if (my $pid = fork()) {
            $nprocs++;

            if ($nprocs >= 3) {
                wait();
                $nprocs--;
            }
        } else {
            open(my $pipe_child, '|-', qw/mysql -u root tpcc/) or die $!;

            foreach my $setting (@settings) {
                print $pipe_child $setting;
            }

            open(my $fh_child, '<', $tempfile) or die $!;
            print "temp $tempfile\n";

            while (my $line_child = <$fh_child>) {
                print $pipe_child $line_child;
            }

            close($fh_child);
            close($pipe_child);
            unlink($tempfile);
            exit(0);
        }
    }
}

close($pipe);