Custom gradle task which copies app-debug.apk to Desktop and renames it to Git's current checked out branch appended with current time in 12-hour format

build.gradle.kts

// 1. Add following snippet in your build.gradle.kts(:app)
// Run this command in terminal -> ./gradlew copyDebugApkToDesktopWithTime

// Note: It will replace "/" in your branch name with "-" as "/" creates a directory.
// fix/bug becomes fix-bug. You can adjust it as per your needs.

import java.text.SimpleDateFormat
import java.util.Date

tasks.register("copyDebugApkToDesktopWithTime") {
    dependsOn("assembleDebug")
    doLast {
        val sourceDir = "build/outputs/apk/debug/app-debug.apk"
        val desktopDir = System.getProperty("user.home") + "/Desktop/"
        val currentTime = SimpleDateFormat("hh-mm-a").format(Date())

        val gitBranch = try {
            val process = Runtime.getRuntime().exec("git rev-parse --abbrev-ref HEAD")
            process.inputStream.bufferedReader().readText().trim().replace("/", "-")
        } catch (e: Exception) {
            "unknown_branch" // Default to a generic name if Git command fails
        }

        project.copy {
            from(sourceDir)
            into(desktopDir)
            rename { "${gitBranch}_${currentTime}.apk" }
        }
    }
}