MacOS Service to convert file path on server to Windows file path and copy to clipboard

Convert Network Path.scpt

# Using Automator -> File -> New -> Service -> Run Applescript

# setting up the basic search and replace function

on searchReplace(theText, SearchString, ReplaceString)
	set OldDelims to AppleScript's text item delimiters
	set AppleScript's text item delimiters to SearchString
	set newText to text items of theText
	set AppleScript's text item delimiters to ReplaceString
	set newText to newText as text
	set AppleScript's text item delimiters to OldDelims
	return newText
end searchReplace

on run {input, parameters}
	
	# Convert path to string for the search and replace
	
	set macPath to POSIX path of (input as string)
	
	# Run the search and replace
	
	set winPath to searchReplace(macPath, "<", "")
	set winPath to searchReplace(winPath, ">.", "")
	set winPath to searchReplace(winPath, ">", "")
	set winPath to searchReplace(winPath, "\\", "/")
	
	# Replace the MacOS volume names with Windows drive letters
	
	set winPath to searchReplace(winPath, "/Volumes/shared", "S:")
	set winPath to searchReplace(winPath, "/Volumes/comm", "P:")
	
	set the clipboard to winPath
	
	# Convert clipboard to plain text so that it doesn't change the font in Microsoft applications
	
	do shell script "pbpaste | pbcopy"
	
	#Just so you know it's done
	
	display notification "Windows path copied to clipboard"
	return input
	
end run