transducer-arrow.clj

(defmacro =>>
  "Makes ->> faster if the first form is a collection, and the last form is `sequence`, `into`, or `reduce`"
  ;; adapted from: https://github.com/divs1210/streamer/blob/master/src/streamer/core.clj
  [coll & xforms-and-term]
  (let [[xforms term] ((juxt butlast last) xforms-and-term)]
    (cond
      ;; sequence
      (or (= term 'sequence)
          (and (list? term)
               (= (first term) 'sequence)))
      (do
        (assert (= 0 (count (rest term))) "`=>> sequence` must have no args")
        `(sequence (comp ~@xforms) ~coll))

      ;; into
      (and (list? term)
           (= (first term) 'into))
      (let [[_ to] term]
        (assert (= 1 (count (rest term))) "`=>> into` must have one arg")
        `(into ~to (comp ~@xforms) ~coll))

      ;; reduce
      (and (list? term)
           (= (first term) 'reduce))
      (let [[_ f init] term]
        (assert (#{1 2} (count (rest term))) "`=>> reduce` must have one or two args")
        (if init
          `(transduce (comp ~@xforms) ~f ~init ~coll)
          `(transduce (comp ~@xforms) ~f ~coll)))

      :else
      (throw (ex-info (format "=>> must end with `(sequence)`, `(into ...)`, or `(reduce ...)`.  got `%s` instead" term)
                      {:term term})))))

(comment
  (require '[criterium.core :refer [quick-bench]])

  (quick-bench
    (->> (range 10)
         (filter even?)
         (map #(Math/sqrt %))
         (reduce *))) ;; => 341 ns

  (quick-bench
    (=>> (range 10)
         (filter even?)
         (map #(Math/sqrt %))
         (reduce *)))) ;; => 206 ns