Require a file, and mock the modules returned to it from require()

mock-require.coffee

Module = require 'module'
# native_module isn't public, mock the needed functionality
NativeModule = do (natives = Object.keys process.binding 'natives') ->
  exists: (name) -> name in natives
  require: require

mock = (request, parent, modules) ->  
  return modules[request] if request of modules
  return NativeModule.require request if NativeModule.exists request

  path = Module._resolveFilename request, parent
  return modules[path] if path of modules

  module = new Module path, parent
  module.require = (filename) -> mock filename, module, modules

  modules[path] = module.exports

  # see https://github.com/joyent/node/commit/bf9d8e9214e2098bacf18416564dc3a91bcdf5d6
  # w.r.t try..finally usage
  hadException = true
  try
    module.load path
    hadException = false
    modules[path] = module.exports
  finally
    delete modules[path] if hadException

module.exports = mock

# Licensed under WTFPL

usage.coffee

mock_require = require 'mock-require'
mock_require 'some_file', module, fs: mocked_fs_module, http: mocked_http_module

# note that `module` is passed as the `parent` argument, so that require() paths are resolved
# relative to the current file path.