(BMS zip compression) BMS の各フォルダを無圧縮zipにしてバックアップフォルダを作る

bmscomporession.bat

REM What do this batch file?
REM   Archive each bms folders using uncompressed zip format, 
REM   and put thost the backup folder.
REM   BMSの各フォルダを無圧縮ZIPでまとめてバックアップフォルダに置きます。
REM How to use
REM   Copy to one up hierarchy of the BMS folder location and execute.
REM   BMSフォルダの一つ上のフォルダに置いてダブルクリックします

@echo off

REM Set the location of 7za.exe.
REM 7zipのコマンドライン版7zaは自分で適当な場所に置いて設定してください。
set exe="C:\7za\7za.exe" 

set T1=%TIME: =0%

REM prefix of the backup folder
set prefix="bms" 

REM --------------------------------

set backupdir=%prefix%%date:~0,4%%date:~5,2%%date:~8,2%

echo "Backup Directory is %backupdir%"
mkdir %backupdir%

for /D %%d in (*) do  (
	cd "%%d"
	mkdir "..\%backupdir%\%%d"
	echo "Change directory %%d"
	for /D %%i in (*) do (
		if not %%i == %backupdir% (
			echo "Compressing %%i -> ..\%backupdir%\%%d\%%i.zip"
			%exe% a "..\%backupdir%\%%d\%%i.zip" -tzip -mx=0 -r "%%i" >> NUL
		)
	)
	cd ..
)

set T2=%TIME: =0%

echo Begin time:%T1%
echo End time:%T2%
echo Done. Backup files are in %backupdir%

PAUSE